reserve x,x0, r,r1,r2 for Real,
      th for Real,

  rr for set,

  rseq for Real_Sequence;

theorem Th36:
  for x be set st x in [.PI/4,PI/2.] holds cosec.x in [.1,sqrt 2.]
proof
  let x be set;
A1: PI/4 < PI/2 by XREAL_1:76;
  assume x in [.PI/4,PI/2.];
  then x in ].PI/4,PI/2.[ \/ {PI/4,PI/2} by A1,XXREAL_1:128;
  then
A2: x in ].PI/4,PI/2.[ or x in {PI/4,PI/2} by XBOOLE_0:def 3;
  per cases by A2,TARSKI:def 2;
  suppose
A3: x in ].PI/4,PI/2.[;
    then
A4: ex s be Real st s=x & PI/4 < s & s < PI/2;
A5: ex s be Real st s=x & PI/4 < s & s < PI/2 by A3;
A6: ].PI/4,PI/2.[ c= [.PI/4,PI/2.] by XXREAL_1:25;
    PI/4 in ].0,PI/2.] & PI/2 in ].0,PI/2.] by A1;
    then
A7: [.PI/4,PI/2.] c= ].0,PI/2.] by XXREAL_2:def 12;
    then
A8: cosec|[.PI/4,PI/2.] is decreasing by Th20,RFUNCT_2:29;
A9: [.PI/4,PI/2.] /\ dom cosec = [.PI/4,PI/2.] by A7,Th4,XBOOLE_1:1,28;
    then PI/2 in [.PI/4,PI/2.] /\ dom cosec by A1;
    then
A10: cosec.x > 1 by A3,A8,A9,A6,A5,Th32,RFUNCT_2:21;
    PI/4 in [.PI/4,PI/2.] by A1;
    then sqrt 2 > cosec.x by A3,A8,A9,A6,A4,Th32,RFUNCT_2:21;
    hence thesis by A10;
  end;
  suppose
    x = PI/4;
    hence thesis by Th32,SQUARE_1:19;
  end;
  suppose
    x = PI/2;
    hence thesis by Th32,SQUARE_1:19;
  end;
end;
