reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;

theorem
  N-min R^2-unit_square = |[0,1]|
proof
  lower_bound (proj1|LSeg(|[0,1]|,|[1,1]|)) = 0
  proof
    set X = LSeg(|[0,1]|,|[1,1]|);
    reconsider Z = (proj1|X).:the carrier of ((TOP-REAL 2)|X) as Subset of
    REAL;
A1: X = [#]((TOP-REAL 2)|X) by PRE_TOPC:def 5
      .= the carrier of ((TOP-REAL 2)|X);
A2: for p be Real st p in Z holds p >= 0
    proof
      let p be Real;
      assume p in Z;
      then consider p0 being object such that
A3:   p0 in the carrier of (TOP-REAL 2)|X and
      p0 in the carrier of (TOP-REAL 2)|X and
A4:   p = (proj1|X).p0 by FUNCT_2:64;
      reconsider p0 as Point of TOP-REAL 2 by A1,A3;
      |[0,1]|`1 = 0 & |[1,1]|`1 = 1 by EUCLID:52;
      then p0`1 >= 0 by A1,A3,TOPREAL1:3;
      hence thesis by A1,A3,A4,PSCOMP_1:22;
    end;
    for q be Real st for p be Real st p in Z holds p >= q
    holds 0 >= q
    proof
A5:   (proj1|X). |[0,1]| = |[0,1]|`1 by PSCOMP_1:22,RLTOPSP1:68
        .= 0 by EUCLID:52;
A6:   |[0,1]| in X by RLTOPSP1:68;
      let q be Real;
      assume for p be Real st p in Z holds p >= q;
      hence thesis by A1,A6,A5,FUNCT_2:35;
    end;
    hence thesis by A2,SEQ_4:44;
  end;
  hence thesis by Th31,Th35;
end;
