reserve T,T1,T2 for TopSpace,
  A,B for Subset of T,
  F for Subset of T|A,
  G,G1, G2 for Subset-Family of T,
  U,W for open Subset of T|A,
  p for Point of T|A,
  n for Nat,
  I for Integer;
reserve Af for finite-ind Subset of T,
  Tf for finite-ind TopSpace;

theorem
  for T st T is T_4 & T is Lindelof & ex F be Subset-Family of T st F is
closed & F is Cover of T & F is countable & F is finite-ind & ind F <= 0 holds
  T is finite-ind & ind T<=0
proof
  let T such that
A1: T is T_4 and
A2: T is Lindelof;
  set CT=[#]T;
  given F be Subset-Family of T such that
A3: F is closed and
A4: F is Cover of T and
A5: F is countable and
A6: F is finite-ind & ind F<=0;
  per cases;
  suppose
    union F is empty;
    then CT={}T by A4,SETFAM_1:45;
    hence thesis by Th6;
  end;
  suppose
A7: union F is non empty;
    then reconsider CT as non empty set;
    consider f be sequence of F such that
A8: F=rng f by A5,A7,CARD_3:96,ZFMISC_1:2;
A9: dom f=NAT by A7,FUNCT_2:def 1,ZFMISC_1:2;
    now
      set CTT=[:bool CT,bool CT:];
      defpred P[object,object] means
for n,A,B st$1=[n,[A,B]] holds(Cl A meets Cl B
implies $2=[A,B]) & (Cl A misses Cl B implies ex G,H be open Subset of T st f.n
      c=G\/H & Cl A c=G & Cl B c=H & $2=[G,H] & Cl G misses Cl H);
      set TOP=the topology of T;
      let A,B be closed Subset of T such that
A10:  A misses B;
A11:  Cl A=A & Cl B=B by PRE_TOPC:22;
A12:  for x be object st x in [:NAT,CTT:]ex y be object st P[x,y]
      proof
        let x be object;
        assume x in [:NAT,CTT:];
        then consider n9,ab be object such that
A13:    n9 in NAT and
A14:    ab in CTT and
A15:    x=[n9,ab] by ZFMISC_1:def 2;
        consider A9,B9 be object such that
A16:    A9 in bool CT & B9 in bool CT and
A17:    ab=[A9,B9] by A14,ZFMISC_1:def 2;
        reconsider A9,B9 as Subset of T by A16;
        per cases;
        suppose
A18:      Cl A9 meets Cl B9;
          take ab;
          let n,A,B;
          assume x=[n,[A,B]];
          then
A19:      ab=[A,B] by A15,XTUPLE_0:1;
          then A=A9 by A17,XTUPLE_0:1;
          hence thesis by A17,A18,A19,XTUPLE_0:1;
        end;
        suppose
A20:      Cl A9 misses Cl B9;
A21:      f.n9 in rng f by A9,A13,FUNCT_1:def 3;
          then reconsider fn=f.n9 as Subset of T by A8;
A22:      fn is closed by A3,A21;
A23:      fn is finite-ind by A6,A21,Th11;
          then
A24:      ind T|fn=ind fn by Lm5;
A25:      ind fn<=0 by A6,A21,Th11;
A26:      [#](T|fn)=fn by PRE_TOPC:def 5;
          then reconsider Af=(Cl A9)/\fn,Bf=(Cl B9)/\fn as Subset of T|fn by
XBOOLE_1:17;
A27:      Af is closed & Bf is closed by A26,PRE_TOPC:13;
          Af misses Bf by A20,XBOOLE_1:76;
          then consider AF,BF be closed Subset of T|fn such that
A28:      AF misses BF and
A29:      AF\/BF=[#](T|fn) and
A30:      Af c=AF and
A31:      Bf c=BF by A2,A22,A25,A23,A24,A27,Th34;
          [#](T|fn)c=[#]T by PRE_TOPC:def 4;
          then reconsider af=AF,bf=BF as Subset of T by XBOOLE_1:1;
A32:      af\/Cl A9 misses bf\/Cl B9
          proof
            assume af\/Cl A9 meets bf\/Cl B9;
            then consider x be object such that
A33:        x in af\/Cl A9 & x in bf\/Cl B9 by XBOOLE_0:3;
            per cases by A33,XBOOLE_0:def 3;
            suppose
              x in af & x in bf or x in Cl A9 & x in Cl B9;
              hence contradiction by A20,A28,XBOOLE_0:3;
            end;
            suppose
A34:          x in af & x in Cl B9;
              then x in Bf by A26,XBOOLE_0:def 4;
              hence contradiction by A28,A31,A34,XBOOLE_0:3;
            end;
            suppose
A35:          x in bf & x in Cl A9;
              then x in Af by A26,XBOOLE_0:def 4;
              hence contradiction by A28,A30,A35,XBOOLE_0:3;
            end;
          end;
          bf is closed & af is closed by A22,A26,TSEP_1:8;
          then consider U,W be open Subset of T such that
A36:      af\/Cl A9 c=U and
A37:      bf\/Cl B9 c=W and
A38:      Cl U misses Cl W by A1,A32,Th2;
          take uw=[U,W];
          let n,A,B;
          assume
A39:      x=[n,[A,B]];
          then
A40:      n=n9 by A15,XTUPLE_0:1;
A41:      ab=[A,B] by A15,A39,XTUPLE_0:1;
          then B=B9 by A17,XTUPLE_0:1;
          then
A42:      Cl B c=W by A37,XBOOLE_1:11;
          af c=U & bf c=W by A36,A37,XBOOLE_1:11;
          then
A43:      f.n c=U\/W by A26,A29,A40,XBOOLE_1:13;
A44:      A=A9 by A17,A41,XTUPLE_0:1;
          then Cl A c=U by A36,XBOOLE_1:11;
          hence thesis by A17,A20,A38,A41,A42,A43,A44,XTUPLE_0:1;
        end;
      end;
      consider GH be Function such that
      dom GH=[:NAT,CTT:] and
A45:  for x be object st x in [:NAT,CTT:] holds P[x,GH.x]
from CLASSES1:
      sch 1( A12);
      deffunc gh(set,set)=GH.[$1,$2];
      consider ghSeq be Function such that
A46:  dom ghSeq=NAT and
A47:  ghSeq.0=[A,B] and
A48:  for n holds ghSeq.(n+1)=gh(n,ghSeq.n) from NAT_1:sch 11;
      defpred R[Nat] means ghSeq.$1 in CTT & for A,B st A=(ghSeq.$1)`1 & B=(
      ghSeq.$1)`2 holds Cl A misses Cl B;
A49:  for n st R[n] holds R[n+1]
      proof
        let n such that
A50:    R[n];
        consider A,B be object such that
A51:    A in bool CT & B in bool CT and
A52:    ghSeq.n=[A,B] by A50,ZFMISC_1:def 2;
        reconsider A,B as Subset of T by A51;
        n in NAT by ORDINAL1:def 12;
        then
A53:    [n,ghSeq.n] in [:NAT,CTT:] by A50,ZFMISC_1:87;
        Cl A misses Cl B by A50,A52;
        then consider G,H be open Subset of T such that
        f.n c=G\/H and
        Cl A c=G and
        Cl B c=H and
A54:    GH.[n,ghSeq.n]=[G,H] and
A55:    Cl G misses Cl H by A45,A52,A53;
A56:    ghSeq.(n+1)=[G,H] by A48,A54;
        thus thesis by A55,A56;
      end;
A57:  R[0] by A10,A11,A47;
A58:  for n holds R[n] from NAT_1:sch 2(A57,A49);
      rng ghSeq c=CTT
      proof
        let y be object;
        assume y in rng ghSeq;
        then ex x be object st x in dom ghSeq & ghSeq.x=y by FUNCT_1:def 3;
        hence thesis by A46,A58;
      end;
      then reconsider ghSeq as sequence of CTT by A46,FUNCT_2:2;
      set g=pr1 ghSeq,h=pr2 ghSeq;
A59:  h.0=[A,B]`2 by A47,FUNCT_2:def 6
        .=B;
      reconsider RngH=rng(h^\1),RngG=rng(g^\1) as Subset-Family of T;
A60:  g.0=[A,B]`1 by A47,FUNCT_2:def 5
        .=A;
A61:  for n holds g.(n+1) in TOP & h.(n+1) in TOP & g.n c=g.(n+1) & h.n
      c=h .(n+1) & g.n misses h.n & f.n c=(g.(n+1))\/h.(n+1)
      proof
        let n;
        consider A,B be object such that
A62:    A in bool CT & B in bool CT and
A63:    ghSeq.n=[A,B] by ZFMISC_1:def 2;
        reconsider A,B as Subset of T by A62;
A64:    n in NAT by ORDINAL1:def 12;
        then
A65:    [n,ghSeq.n] in [:NAT,CTT:] by ZFMISC_1:87;
A66:    A=[A,B]`1;
        then
A67:    A=g.n by A46,A64,A63,MCART_1:def 12;
A68:    B=[A,B]`2;
        then
A69:    B=h.n by A46,A64,A63,MCART_1:def 13;
        Cl A misses Cl B by A58,A66,A68,A63;
        then consider G,H be open Subset of T such that
A70:    f.n c=G\/H and
A71:    Cl A c=G and
A72:    Cl B c=H and
A73:    GH.[n,ghSeq.n]=[G,H] and
        Cl G misses Cl H by A45,A63,A65;
A74:    ghSeq.(n+1)=[G,H] by A48,A73;
A75:    G=[G,H]`1
          .=g.(n+1) by A46,A74,MCART_1:def 12;
        hence g.(n+1) in TOP by PRE_TOPC:def 2;
A76:    H=[G,H]`2
          .=h.(n+1) by A46,A74,MCART_1:def 13;
        hence h.(n+1) in TOP by PRE_TOPC:def 2;
        A c=Cl A by PRE_TOPC:18;
        hence g.n c=g.(n+1) by A67,A71,A75;
        B c=Cl B by PRE_TOPC:18;
        hence h.n c=h.(n+1) by A69,A72,A76;
        A c=Cl A & B c=Cl B by PRE_TOPC:18;
        hence g.n misses h.n by A58,A66,A67,A68,A69,A63,XBOOLE_1:64;
        thus thesis by A70,A75,A76;
      end;
      then for n be Nat holds g.n c=g.(n+1);
      then
A77:  g is non-descending by KURATO_0:def 4;
A78:  RngH is open
      proof
A79:    RngH={h.n where n is Nat:n>=1} by SETLIM_1:6;
        let A be Subset of T;
        assume A in RngH;
        then consider n be Nat such that
A80:    h.n=A and
A81:    n>=1 by A79;
        reconsider n1=n-1 as Nat by A81,NAT_1:21;
        h.(n1+1) in TOP by A61;
        hence thesis by A80,PRE_TOPC:def 2;
      end;
      RngG is open
      proof
A82:    RngG={g.n where n is Nat:n>=1} by SETLIM_1:6;
        let A be Subset of T;
        assume A in RngG;
        then consider n be Nat such that
A83:    g.n=A and
A84:    n>=1 by A82;
        reconsider n1=n-1 as Nat by A84,NAT_1:21;
        g.(n1+1) in TOP by A61;
        hence thesis by A83,PRE_TOPC:def 2;
      end;
      then reconsider
      unionG=union RngG,unionH=union RngH as open Subset of T by A78,TOPS_2:19;
      for n be Nat holds h.n c=h.(n+1) by A61;
      then
A85:  h is non-descending by KURATO_0:def 4;
A86:  unionH misses unionG
      proof
        assume unionH meets unionG;
        then consider x be object such that
A87:    x in unionH and
A88:    x in unionG by XBOOLE_0:3;
        consider H be set such that
A89:    x in H and
A90:    H in RngH by A87,TARSKI:def 4;
        RngH={h.n where n is Nat:n>=1} by SETLIM_1:6;
        then consider i be Nat such that
A91:    h.i=H and
        i>=1 by A90;
        consider G be set such that
A92:    x in G and
A93:    G in RngG by A88,TARSKI:def 4;
        RngG={g.n where n is Nat:n>=1} by SETLIM_1:6;
        then consider j be Nat such that
A94:    g.j=G and
        j>=1 by A93;
        per cases;
        suppose
A95:      i<=j;
A96:      g.j misses h.j by A61;
          h.i c=h.j by A85,A95,PROB_1:def 5;
          hence contradiction by A92,A94,A89,A91,A96,XBOOLE_0:3;
        end;
        suppose
A97:      i>=j;
A98:      g.i misses h.i by A61;
          g.j c=g.i by A77,A97,PROB_1:def 5;
          hence contradiction by A92,A94,A89,A91,A98,XBOOLE_0:3;
        end;
      end;
A99:  CT c=unionH\/unionG
      proof
        let x be object;
        assume x in CT;
        then reconsider x as Point of T;
        union F=CT by A4,SETFAM_1:45;
        then consider X be set such that
A100:   x in X and
A101:   X in rng f by A8,TARSKI:def 4;
        consider n be object such that
A102:   n in dom f and
A103:   f.n=X by A101,FUNCT_1:def 3;
        reconsider n as Element of NAT by A102;
A104:   n+1>=1 by NAT_1:12;
A105:   f.n c=(g.(n+1))\/h.(n+1) by A61;
        per cases by A100,A103,A105,XBOOLE_0:def 3;
        suppose
A106:     x in g.(n+1);
          RngG={g.i where i is Nat:i>=1} by SETLIM_1:6;
          then g.(n+1) in RngG by A104;
          then x in unionG by A106,TARSKI:def 4;
          hence thesis by XBOOLE_0:def 3;
        end;
        suppose
A107:     x in h.(n+1);
          RngH={h.i where i is Nat:i>=1} by SETLIM_1:6;
          then h.(n+1) in RngH by A104;
          then x in unionH by A107,TARSKI:def 4;
          hence thesis by XBOOLE_0:def 3;
        end;
      end;
      then CT=unionH\/unionG;
      then unionH=unionG` & unionG=unionH` by A86,PRE_TOPC:5;
      then reconsider unionG,unionH as closed Subset of T;
      take unionG,unionH;
      thus unionG misses unionH by A86;
      thus unionG\/unionH=[#]T by A99;
      RngG={g.i where i is Nat:i>=1} by SETLIM_1:6;
      then g.1 in RngG;
      then
A108: g.1 c=unionG by ZFMISC_1:74;
      g.0 c=g.(0+1) by A61;
      hence A c=unionG by A108,A60;
      RngH={h.i where i is Nat:i>=1} by SETLIM_1:6;
      then h.1 in RngH;
      then
A109: h.1 c=unionH by ZFMISC_1:74;
      h.0 c=h.(0+1) by A61;
      hence B c=unionH by A109,A59;
    end;
    hence thesis by A1,Th32;
  end;
end;
