reserve N for Nat;
reserve n,m,n1,n2 for Nat;
reserve q,r,r1,r2 for Real;
reserve x,y for set;
reserve w,w1,w2,g,g1,g2 for Point of TOP-REAL N;
reserve seq,seq1,seq2,seq3,seq9 for Real_Sequence of N;

theorem Th36:
  seq is convergent & seq9 is convergent implies seq + seq9 is convergent
proof
  assume that
A1: seq is convergent and
A2: seq9 is convergent;
  consider g1 such that
A3: for r st 0<r ex n st for m st n<=m holds |.seq.m-g1.|<r by A1;
  consider g2 such that
A4: for r st 0<r ex n st for m st n<=m holds |.seq9.m-g2.|<r by A2;
  take g=g1+g2;
  let r;
  assume
A5: 0<r;
  then consider n1 such that
A6: for m st n1<=m holds |.seq.m-g1.|<r/2 by A3,XREAL_1:215;
  consider n2 such that
A7: for m st n2<=m holds |.seq9.m-g2.|<r/2 by A4,A5,XREAL_1:215;
  take k=n1+n2;
  let m;
  assume
A8: k<=m;
  n2<=k by NAT_1:12;
  then n2<=m by A8,XXREAL_0:2;
  then
A9: |.seq9.m-g2.|<r/2 by A7;
A10: |.(seq+seq9).m-g.|=|.seq.m+seq9.m-(g1+g2).| by Th4
    .=|.seq.m+(seq9.m-(g1+g2)).| by RLVECT_1:def 3
    .=|.seq.m+((-(g1+g2))+seq9.m).|
    .=|.seq.m+-(g1+g2)+seq9.m.| by RLVECT_1:def 3
    .=|.seq.m-(g1+g2)+seq9.m.|
    .=|.seq.m-g1-g2+seq9.m.| by RLVECT_1:27
    .=|.seq.m-g1+-g2+seq9.m.|
    .=|.seq.m-g1+(seq9.m+-g2).| by RLVECT_1:def 3
    .=|.seq.m-g1+(seq9.m-g2).|;
A11: |.seq.m-g1+(seq9.m-g2).|<=|.seq.m-g1.|+|.seq9.m-g2.| by Th29;
  n1<=n1+n2 by NAT_1:12;
  then n1<=m by A8,XXREAL_0:2;
  then |.seq.m-g1.|<r/2 by A6;
  then |.seq.m-g1.|+|.seq9.m-g2.|<r/2+r/2 by A9,XREAL_1:8;
  hence thesis by A10,A11,XXREAL_0:2;
end;
