
theorem Th36:
  for L being complete LATTICE, c being closure Function of L,L holds
  Image c is directed-sups-inheriting iff
  inclusion c is directed-sups-preserving
proof
  let L be complete LATTICE, c be closure Function of L,L;
  set ic = inclusion c;
  thus Image c is directed-sups-inheriting implies
  inclusion c is directed-sups-preserving
  proof
    assume
A1: Image c is directed-sups-inheriting;
    let D be Subset of Image c;
    assume
A2: D is non empty directed;
    then reconsider E = D as non empty directed Subset of L by YELLOW_2:7;
A3: ic.:D = E by WAYBEL15:12;
    assume ex_sup_of D, Image c;
    thus ex_sup_of ic.:D, L by YELLOW_0:17;
    hence sup (ic.:D) = sup D by A1,A2,A3,WAYBEL_0:7
      .= ic.sup D by FUNCT_1:18;
  end;
  assume
A4: inclusion c is directed-sups-preserving;
  let X be directed Subset of Image c;
  assume
A5: X <> {};
  assume ex_sup_of X,L;
A6: ic preserves_sup_of X by A4,A5;
  ex_sup_of X, Image c by YELLOW_0:17;
  then sup (ic.:X) = ic.sup X by A6
    .= sup X by FUNCT_1:18;
  then sup (ic.:X) in the carrier of Image c;
  hence thesis by WAYBEL15:12;
end;
