reserve m,n for Nat;
reserve i,j for Integer;
reserve S for non empty addMagma;
reserve r,r1,r2,s,s1,s2,t,t1,t2 for Element of S;
reserve G for addGroup-like non empty addMagma;
reserve e,h for Element of G;
reserve G for addGroup;
reserve f,g,h for Element of G;
reserve u for UnOp of G;
reserve A for Abelian addGroup;
reserve a,b for Element of A;
reserve x for object;
reserve y,y1,y2,Y,Z for set;
reserve k for Nat;
reserve G for addGroup;
reserve a,g,h for Element of G;
reserve A for Subset of G;
reserve G for non empty addMagma,
  A,B,C for Subset of G;
reserve a,b,g,g1,g2,h,h1,h2 for Element of G;
reserve G for addGroup-like non empty addMagma;
reserve h,g,g1,g2 for Element of G;
reserve A for Subset of G;
reserve H for Subgroup of G;
reserve h,h1,h2 for Element of H;
reserve G,G1,G2,G3 for addGroup;
reserve a,a1,a2,b,b1,b2,g,g1,g2 for Element of G;
reserve A,B for Subset of G;
reserve H,H1,H2,H3 for Subgroup of G;
reserve h,h1,h2 for Element of H;
reserve x,y,y1,y2 for set;
reserve G for addGroup;
reserve a,b,c,d,g,h for Element of G;
reserve A,B,C,D for Subset of G;
reserve H,H1,H2,H3 for Subgroup of G;
reserve n for Nat;
reserve i for Integer;
reserve L for Subset of Subgroups G;
reserve N2 for normal Subgroup of G;
reserve S, R for 1-sorted,
  X for Subset of R,
  T for TopStruct,
  x for set;
reserve H for non empty addMagma,
   P, Q, P1, Q1 for Subset of H,
   h for Element of H;
 reserve a for Element of G;

theorem
  for G being TopologicaladdGroup, B being Basis of 0_G,
      M being dense Subset of G holds
    { V + x where V is Subset of G, x is Point of G: V in B & x in M }
      is Basis of G
proof
  let G be TopologicaladdGroup, B be Basis of 0_G, M be dense Subset of G;
  set Z = { V + x where V is Subset of G, x is Point of G: V in B & x in M };
A1: Z c= the topology of G
  proof
    let a be object;
    assume a in Z;
    then consider V being Subset of G, x being Point of G such that
A2: a = V+x and
A3: V in B and
    x in M;
    reconsider V as Subset of G;
    V is open by A3,YELLOW_8:12;
    hence thesis by A2,PRE_TOPC:def 2;
  end;
A4: for W being Subset of G st W is open for a being Point of G st a in W ex
  V being Subset of G st V in Z & a in V & V c= W
  proof
A5: 0_G + (- 0_G) = 0_G + 0_G by Th8
      .= 0_G by Def4;
    let W be Subset of G such that
A6: W is open;
    let a be Point of G such that
A7: a in W;
    0_G = a+(-a) by Def5;
    then W +(-a) is a_neighborhood of 0_G + (- 0_G)
    by A7,A6,A5,CONNSP_2:3,Th28;
    then consider V being open a_neighborhood of 0_G such that
A8: V + (-V) c= W + (-a) by Th54;
    consider E being Subset of G such that
A9: E in B and
A10: E c= V by CONNSP_2:4,YELLOW_8:13;
    E is open & E <> {} by A9,YELLOW_8:12;
    then consider d being object such that
A11: d in (a + (-M)) /\ E by XBOOLE_0:4,TOPS_1:45;
    reconsider d as Point of G by A11;
    take I = E+( (-d) +a);
    d in a + (-M) by A11,XBOOLE_0:def 4;
    then consider m being Point of G such that
A12: d = a+m and
A13: m in -M by Th27;
    (-d)+a = (-d)+a+0_G by Def4
      .= (-d)+a+(m+(-m)) by Def5
      .= (-d)+a+m+(-m) by RLVECT_1:def 3
      .= (-d)+d+(-m) by A12,RLVECT_1:def 3
      .= 0_G+(-m) by Def5
      .= (-m) by Def4;
    then (-d)+a in M by A13,Th7;
    hence I in Z by A9;
A14: 0_G+a = a by Def4;
A15: d in E by A11,XBOOLE_0:def 4;
    E+(-d) c= V+(-V)
    proof
      let q be object;
      assume q in E+(-d);
      then
A16:  ex v being Point of G st q = v+(-d) & v in E by Th28;
      (-d) in (-V) by A10,A15;
      hence thesis by A10,A16;
    end;
    then E + (-d) c= W + (-a) by A8;
    then
A17: E + (-d) + a c= W + (-a) + a by Th5;
    d+(-d) = 0_G by Def5;
    then 0_G in E+(-d) by A15,Th28;
    then a in E+(-d)+a by A14,Th28;
    hence a in I by ThB34;
    W +(-a)+a = W+(-a+a) by ThB34
      .= W+0_G by Def5
      .= W by Th37;
    hence thesis by A17,ThB34;
  end;
  Z c= bool the carrier of G
  proof
    let a be object;
    assume a in Z;
    then
    ex V being Subset of G, x being Point of G st a = V+x & V in B & x in M;
    hence thesis;
  end;
  hence thesis by A1,A4,YELLOW_9:32;
end;
