
theorem
  for X be ComplexNormSpace, seq be sequence of X holds
   (for n be Nat holds seq.n<>0.X) &
   (ex m be Nat st for n be Nat st
   n >=m holds ||.seq.||.(n+1)/||.seq.||.n >= 1) implies seq is not
  norm_summable
proof
  let X be ComplexNormSpace;
  let seq be sequence of X;
  assume that
A1: for n be Nat holds seq.n <> 0.X and
A2: ex m be Nat st for n be Nat st n >=m holds ||.
  seq.||.(n+1)/||.seq.||.n >= 1;
  consider m be Nat such that
A3: for n be Nat st n >=m holds ||.seq.||.(n+1)/||.seq.||.n
  >= 1 by A2;
A4: now
    let n be Nat such that
A5: n>=m;
A6: 0 <=||.seq.||.n by Th2;
A7: 0 <=||.seq.||.(n+1) by Th2;
A8: abs((||.seq.||)).(n+1) =|.(||.seq.||).(n+1).| by SEQ_1:12
      .=||.seq.||.(n+1) by A7,ABSVALUE:def 1;
    abs((||.seq.||)).n =|.(||.seq.||).n.| by SEQ_1:12
      .=||.seq.||.n by A6,ABSVALUE:def 1;
    hence abs((||.seq.||)).(n+1)/abs((||.seq.||)).n >= 1 by A3,A5,A8;
  end;
  now
    let n be Nat;
    seq.n <> 0.X by A1;
    then ||.seq.n.||<>0 by NORMSP_0:def 5;
    hence ||.seq.||.n <>0 by NORMSP_0:def 4;
  end;
  hence ||.seq.|| is not summable by A4,SERIES_1:39;
end;
