
theorem Th37:
  for C1, C2 being Coherence_Space for f,g being U-stable Function
  of C1,C2 st Trace f = Trace g holds f = g
proof
  let C1, C2 be Coherence_Space;
  let f,g be U-stable Function of C1,C2;
A1: dom f = C1 by FUNCT_2:def 1;
A2: dom g = C1 by FUNCT_2:def 1;
A3: now
    let a be Element of C1;
    let f,g be U-stable Function of C1,C2;
A4: dom g = C1 by FUNCT_2:def 1;
    assume
A5: Trace f = Trace g;
    thus f.:Fin a c= g.:Fin a
    proof
      let y be object;
      assume y in f.:Fin a;
      then consider x being object such that
      x in dom f and
A6:   x in Fin a and
A7:   y = f.x by FUNCT_1:def 6;
      f.x c= g.x & g.x c= f.x by A5,A6,Th36;
      then f.x = g.x;
      hence thesis by A4,A6,A7,FUNCT_1:def 6;
    end;
  end;
  assume
A8: Trace f = Trace g;
  now
    let a be Element of C1;
    f.:Fin a c= g.:Fin a & g.:Fin a c= f.:Fin a by A8,A3;
    then
A9: f.:Fin a = g.:Fin a;
    thus f.a = union (f.:Fin a) by A1,Th20
      .= g.a by A2,A9,Th20;
  end;
  hence thesis by FUNCT_2:63;
end;
