reserve n for Nat,
        lambda,lambda2,mu,mu2 for Real,
        x1,x2 for Element of REAL n,
        An,Bn,Cn for Point of TOP-REAL n,
        a for Real;
 reserve Pn,PAn,PBn for Element of REAL n,
         Ln for Element of line_of_REAL n;
reserve A,B,C for Point of TOP-REAL 2;
reserve x,y,z,y1,y2 for Element of REAL 2;
reserve L,L1,L2,L3,L4 for Element of line_of_REAL 2;
reserve D,E,F for Point of TOP-REAL 2;
reserve b,c,d,r,s for Real;

theorem Th29:
  A<>B & r is positive & r <> 1 & |.A-C.| = r * |.A-B.| implies
  A,B,C are_mutually_distinct
  proof
    assume that
A1: A<>B and
A2: r is positive and
A3: r <> 1 and
A4: |.A-C.| = r * |.A-B.|;
    now
      hereby
        assume A=C;
        then r * |.A-B.| = r * 0 by A4,EUCLID_6:42;
        then |.A-B.| = 0 by A2,XCMPLX_1:5;
        hence contradiction by A1,EUCLID_6:42;
      end;
      hereby
        assume B=C;
        then 1 * |.A-B.| = r * |.A-B.| & |.A-B.| <> 0 by A1,A4,EUCLID_6:42;
        hence contradiction by A3,XCMPLX_1:5;
      end;
    end;
    hence thesis by A1;
  end;
