reserve FT for non empty RelStr,
  A,B,C for Subset of FT;

theorem Th36:
  FT is filled symmetric connected & A is connected & [#]FT \ A =
  B \/ C & B,C are_separated implies A \/ B is connected
proof
  assume that
A1: FT is filled symmetric and
A2: FT is connected and
A3: A is connected and
A4: [#]FT \ A = B \/ C and
A5: B,C are_separated;
A6: [#]FT is connected by A2;
  now
    let P,Q be Subset of FT such that
A7: A \/ B = P \/ Q and
    P misses Q and
A8: P,Q are_separated;
A9: [#]FT = A \/ (B \/ C) by A4,XBOOLE_1:45
      .= P \/ Q \/ C by A7,XBOOLE_1:4;
A10: now
A11:  [#]FT = P \/ (Q \/ C) by A9,XBOOLE_1:4;
      assume A c= Q;
      then P misses A by A1,A8,Th28,FINTOPO4:6;
      then P c= B by A7,XBOOLE_1:7,73;
      then
A12:  P,C are_separated by A5,Th28;
      then P misses Q \/ C by A1,A8,Th29,FINTOPO4:6;
      hence P = {}FT or Q = {}FT by A6,A8,A12,A11,Th3,Th29;
    end;
    now
A13:  [#]FT = Q \/ (P \/ C) by A9,XBOOLE_1:4;
      assume A c= P;
      then Q misses A by A1,A8,Th28,FINTOPO4:6;
      then Q c= B by A7,XBOOLE_1:7,73;
      then
A14:  Q,C are_separated by A5,Th28;
      then Q misses P\/C by A1,A8,Th29,FINTOPO4:6;
      hence P = {}FT or Q = {}FT by A6,A8,A14,A13,Th3,Th29;
    end;
    hence P = {}FT or Q = {}FT by A1,A3,A7,A8,A10,Th32,XBOOLE_1:7;
  end;
  hence thesis by A1,Th6;
end;
