
theorem Th37:
  for T being non empty TopStruct, S being sequence of T, P being
  Permutation of NAT, x being Point of T st S is_convergent_to x holds S*P
  is_convergent_to x
proof
  let T be non empty TopStruct, S be sequence of T, P be Permutation of NAT, x
  be Point of T;
  assume
A1: S is_convergent_to x;
  for U1 being Subset of T st U1 is open & x in U1
   ex n being Nat st for m being Nat st n <= m holds (S*P).m in U1
  proof
    let U1 be Subset of T;
    defpred P[set] means $1 in U1;
    assume
A2: U1 is open & x in U1;
A3: ex n being Element of NAT st for m being Element of NAT, x being Point
    of T st n<=m & x=S.m holds P[x]
    proof
      consider n being Nat such that
A4:   for m being Nat st n<=m holds S.m in U1 by A1,A2;
       reconsider n as Element of NAT by ORDINAL1:def 12;
      take n;
      let m be Element of NAT, x be Point of T;
      assume n<=m & x=S.m;
      hence thesis by A4;
    end;
    consider n being Element of NAT such that
A5:  for m being Element of NAT st n <= m holds P[(S*P).m] from PermSeq2(A3);
   take n;
   let m be Nat;
    m in NAT by ORDINAL1:def 12;
   hence thesis by A5;
  end;
  hence thesis;
end;
