reserve k, m, n, p, K, N for Nat;
reserve i for Integer;
reserve x, y, eps for Real;
reserve seq, seq1, seq2 for Real_Sequence;
reserve sq for FinSequence of REAL;

theorem Th37:
  n!*Partial_Sums(eseq).n is integer
proof
  defpred P[Nat] means
   $1<=n implies n!*Partial_Sums(eseq).$1 is integer;
  now
    let k;
    assume
A1: k<=n implies n!*Partial_Sums(eseq).k is integer;
    assume
A2: k+1<=n;
    k+0<=k+1 by XREAL_1:6;
    then reconsider i = n!*Partial_Sums(eseq).k as Integer by A1,A2,XXREAL_0:2;
    n!*eseq.(k+1) = (n!)/((k+1)!) by Th32;
    then reconsider j = n!*eseq.(k+1) as Integer by A2,Th36;
A3: i+j is Integer;
    n!*Partial_Sums(eseq).(k+1) = n!*(Partial_Sums(eseq).k+eseq.(k+1)) by
SERIES_1:def 1
      .= n!*Partial_Sums(eseq).k+n!*eseq.(k+1);
    hence n!*Partial_Sums(eseq).(k+1) is integer by A3;
  end;
  then
A4: P[k] implies P[k+1];
  now
    assume 0<=n;
    n!*Partial_Sums(eseq).0 = n!*eseq.0 by SERIES_1:def 1
      .= (n!)/(0!) by Th32;
    hence n!*Partial_Sums(eseq).0 is integer by Th36;
  end;
  then
A5: P[0];
  for k holds P[k] from NAT_1:sch 2(A5,A4);
  hence thesis;
end;
