reserve a, b, c, d, r, s for Real,
  n for Element of NAT,
  p, p1, p2 for Point of TOP-REAL 2,
  x, y for Point of TOP-REAL n,
  C for Simple_closed_curve,
  A, B, P for Subset of TOP-REAL 2,
  U, V for Subset of (TOP-REAL 2)|C`,
  D for compact with_the_max_arc Subset of TOP-REAL 2;

theorem Th37:
  for T being non empty TopSpace, a, b, c being Point of T
  for f being Path of a,b, g being Path of b,c st
  a,b are_connected & b,c are_connected holds rng(f+g) = rng f \/ rng g
proof
  let T be non empty TopSpace;
  let a, b, c be Point of T;
  let f be Path of a,b;
  let g be Path of b,c;
  assume that
A1: a,b are_connected and
A2: b,c are_connected;
  thus rng(f+g) c= rng f \/ rng g
  proof
    let y be object;
    assume y in rng(f+g);
    then consider x being object such that
A3: x in dom(f+g) and
A4: y = (f+g).x by FUNCT_1:def 3;
    reconsider x as Point of I[01] by A3;
    per cases;
    suppose
A5:   x <= 1/2;
      then
A6:   (f+g).x = f.(2*x) by A1,A2,BORSUK_2:def 5;
A7:   rng f c= rng f \/ rng g by XBOOLE_1:7;
A8:   dom f = the carrier of I[01] by FUNCT_2:def 1;
      2*x is Point of I[01] by A5,BORSUK_6:3;
      then y in rng f by A4,A6,A8,FUNCT_1:def 3;
      hence thesis by A7;
    end;
    suppose
A9:   1/2 <= x;
      then
A10:  (f+g).x = g.(2*x-1) by A1,A2,BORSUK_2:def 5;
A11:  rng g c= rng f \/ rng g by XBOOLE_1:7;
A12:  dom g = the carrier of I[01] by FUNCT_2:def 1;
      2*x-1 is Point of I[01] by A9,BORSUK_6:4;
      then y in rng g by A4,A10,A12,FUNCT_1:def 3;
      hence thesis by A11;
    end;
  end;
A13: rng f c= rng(f+g) by A1,A2,Th33;
  rng g c= rng(f+g) by A1,A2,Th35;
  hence thesis by A13,XBOOLE_1:8;
end;
