reserve L for Ortholattice,
  a, b, c for Element of L;

theorem
  L is orthomodular iff for a,b st a [= b holds (a "\/" b) "/\" (b "\/"
  a`) = (a "/\" b) "\/" (b "/\" a`)
proof
  thus L is orthomodular implies for a,b st a [= b holds (a "\/" b) "/\" (b
  "\/" a`) = (a "/\" b) "\/" (b "/\" a`)
  proof
    assume
A1: L is orthomodular;
    let a,b;
    assume
A2: a [= b;
    (a"/\"b)[=(a"\/"b) & (b"/\"a`)[=(a"\/"b) by FILTER_0:3,LATTICES:6;
    then
A3: (a"/\"b)"\/" (b"/\"a`)[=(a"\/"b) by FILTER_0:6;
    (a"/\"b)[=(b"\/"a`) & (b"/\"a`)[=(b"\/"a`) by FILTER_0:3,LATTICES:6;
    then (a"/\"b)"\/" (b"/\"a`)[=(b"\/"a`) by FILTER_0:6;
    then
A4: (a"/\"b)"\/" (b"/\"a`)[=(a"\/"b)"/\"(b"\/"a`) by A3,FILTER_0:7;
A5: (a"\/"b)"/\"(b"\/"a`)[= a"\/"b by LATTICES:6;
    a "\/"b = ((a"\/"b)"/\"a)"\/"((a"\/"b)"/\"a`) by A1,Th36
      .= (b"/\"a)"\/"((a"\/"b)"/\"a`) by A2
      .= (b"/\"a)"\/"(b"/\"a`) by A2;
    hence thesis by A4,A5,LATTICES:8;
  end;
  assume
A6: for a,b st a[=b holds (a "\/" b) "/\" (b "\/" a`) = (a "/\" b) "\/"
  (b "/\" a`);
  let a,b;
  assume
A7: a [= b;
  then (a "\/" b) "/\" (b "\/" a`) = (a "/\" b) "\/" (b "/\" a`) by A6
    .= a "\/" (a` "/\" b) by A7,LATTICES:4;
  hence a "\/" (a` "/\" b) = b "/\" (b "\/" a`) by A7
    .= b by LATTICES:def 9;
end;
