reserve n,m,k for Nat;
reserve r,r1 for Real;
reserve f,seq,seq1 for Real_Sequence;
reserve x,y for set;
reserve e1,e2 for ExtReal;
reserve Nseq for increasing sequence of NAT;

theorem
  (seq is bounded implies for r holds r(#)seq is bounded) & (seq is
  bounded implies -seq is bounded) & (seq is bounded iff abs seq is bounded)
proof
  thus seq is bounded implies for r holds r(#)seq is bounded
  proof
    assume
A1: seq is bounded;
    let r;
    per cases;
    suppose
      0<r;
      hence thesis by A1;
    end;
    suppose
      0=r;
      hence thesis by Th36;
    end;
    suppose
      r<0;
      hence thesis by A1;
    end;
  end;
  thus seq is bounded implies -seq is bounded;
  thus seq is bounded implies abs seq is bounded;
  assume abs seq is bounded;
  then consider r be Real such that
A2: 0<r and
A3: for n be Nat holds |.abs seq.n.|<r by SEQ_2:3;
  now
    let n be Nat;
    |.abs seq .n.|=|.|.seq.n.|.| by SEQ_1:12
      .=|.seq.n.|;
    hence |.seq.n.| < r by A3;
  end;
  hence thesis by A2,SEQ_2:3;
end;
