reserve p, q, x, y for Real,
  n for Nat;
reserve X for non empty TopSpace,
  a, b, c, d, e, f for Point of X,
  T for non empty pathwise_connected TopSpace,
  a1, b1, c1, d1, e1, f1 for Point of T;

theorem Th37:
  a,b are_connected & b,c are_connected & b,d are_connected
implies for A being Path of a,b, B being Path of d,b, C being Path of b,c holds
  A+-B+B+C, A+C are_homotopic
proof
  assume that
A1: a,b are_connected and
A2: b,c are_connected and
A3: b,d are_connected;
  let A be Path of a,b, B be Path of d,b, C be Path of b,c;
A4: A+-B+B+C, A+(-B+B+C) are_homotopic by A1,A2,A3,Th33;
  set X = the constant Path of b,b;
  C,C are_homotopic & -B+B, X are_homotopic by A2,A3,BORSUK_2:12,BORSUK_6:86;
  then
A5: -B+B+C, X+C are_homotopic by A2,BORSUK_6:75;
  X+C, C are_homotopic by A2,BORSUK_6:82;
  then
A6: -B+B+C, C are_homotopic by A5,BORSUK_6:79;
  A,A are_homotopic by A1,BORSUK_2:12;
  then A+(-B+B+C), A+C are_homotopic by A1,A2,A6,BORSUK_6:75;
  hence thesis by A4,BORSUK_6:79;
end;
