reserve N for Nat;
reserve n,m,n1,n2 for Nat;
reserve q,r,r1,r2 for Real;
reserve x,y for set;
reserve w,w1,w2,g,g1,g2 for Point of TOP-REAL N;
reserve seq,seq1,seq2,seq3,seq9 for Real_Sequence of N;

theorem Th37:
  seq is convergent & seq9 is convergent implies lim (seq + seq9)=
  (lim seq)+(lim seq9)
proof
  assume that
A1: seq is convergent and
A2: seq9 is convergent;
A3: now
    let r;
    assume 0<r;
    then
A4: 0<r/2 by XREAL_1:215;
    then consider n1 such that
A5: for m st n1<=m holds |.seq.m-lim (seq).|<r/2 by A1,Def9;
    consider n2 such that
A6: for m st n2<=m holds |.seq9.m-lim (seq9).|<r/2 by A2,A4,Def9;
    take k=n1+n2;
    let m such that
A7: k<=m;
    n2<=k by NAT_1:12;
    then n2<=m by A7,XXREAL_0:2;
    then
A8: |.seq9.m-(lim seq9).|<r/2 by A6;
A9: |.((seq+seq9).m)-((lim seq)+(lim seq9)).| =|.((seq+seq9).m)-(lim seq)
    -(lim seq9).| by RLVECT_1:27
      .=|.seq.m+seq9.m-(lim seq)-(lim seq9).| by Th4
      .=|.seq.m+(seq9.m-(lim seq))-(lim seq9).| by RLVECT_1:def 3
      .=|.seq.m+(-(lim seq)+seq9.m)-(lim seq9).|
      .=|.seq.m+-(lim seq)+seq9.m-(lim seq9).| by RLVECT_1:def 3
      .=|.seq.m-(lim seq)+seq9.m-(lim seq9).|
      .=|.seq.m-(lim seq)+(seq9.m-(lim seq9)).| by RLVECT_1:def 3;
A10: |.seq.m-(lim seq)+(seq9.m-(lim seq9)).|<= |.seq.m-(lim seq).|+|.seq9.
    m-(lim seq9).| by Th29;
    n1<=n1+n2 by NAT_1:12;
    then n1<=m by A7,XXREAL_0:2;
    then |.seq.m-lim(seq).|<r/2 by A5;
    then |.seq.m-(lim seq).|+|.seq9.m-(lim seq9).|<r/2+r/2 by A8,XREAL_1:8;
    hence |.((seq+seq9).m)-((lim seq)+(lim seq9)).|<r by A9,A10,XXREAL_0:2;
  end;
  seq+seq9 is convergent by A1,A2,Th36;
  hence thesis by A3,Def9;
end;
