
theorem :: 1.8. COROLLARY, (1) <=> (2), p. 182
  for L being complete LATTICE, c being closure Function of L,L holds
  Image c is directed-sups-inheriting iff
  for X being Scott TopAugmentation of Image c
  for Y being Scott TopAugmentation of L
  for f being Function of Y,X st f = c holds f is open
proof
  let L be complete LATTICE, c be closure Function of L,L;
A1: LowerAdj inclusion c = corestr c by Th35;
A2: corestr c = c by WAYBEL_1:30;
A3: inclusion c is infs-preserving Function of Image c, L by Th35;
A4: Image c is directed-sups-inheriting iff inclusion c is
  directed-sups-preserving by Th36;
  hence Image c is directed-sups-inheriting implies
  for X being Scott TopAugmentation of Image c
  for Y being Scott TopAugmentation of L
  for f being Function of Y,X st f = c holds f is open by A1,A2,A3,Th28;
  assume
A5: for X being Scott TopAugmentation of Image c
  for Y being Scott TopAugmentation of L
  for f being Function of Y,X st f = c holds f is open;

set X = the Scott TopAugmentation of Image c,Y = the Scott TopAugmentation of L
;
A6: the RelStr of X = the RelStr of Image c by YELLOW_9:def 4;
  the RelStr of Y = the RelStr of L by YELLOW_9:def 4;
  then reconsider f = c as Function of Y,X by A2,A6;
  f is open by A5;
  hence thesis by A1,A2,A3,A4,Th28;
end;
