
theorem Th29:
  for a being non zero Real
  for N being invertible Matrix of 3,F_Real st N = symmetric_3(a,a,-a,0,0,0)
  holds homography(N).:absolute = absolute
  proof
    let a be non zero Real;
    let N be invertible Matrix of 3,F_Real;
    assume
A1: N = symmetric_3(a,a,-a,0,0,0);
A2: homography(N).:absolute c= absolute
    proof
      let x be object;
      assume x in homography(N).:absolute;
      then consider y be object such that
A3:   y in dom homography(N) and
A4:   y in absolute and
A5:   (homography(N)).y = x by FUNCT_1:def 6;
A6:   rng homography(N) c= the carrier of ProjectiveSpace TOP-REAL 3
        by RELAT_1:def 19;
      reconsider y9 = y as Element of ProjectiveSpace TOP-REAL 3 by A3;
      consider u9 be non zero Element of TOP-REAL 3 such that
A7:   (u9.1)^2 + (u9.2)^2 = 1 & u9.3 = 1 & y = Dir u9 by A4,BKMODEL1:89;
      consider u,v be Element of TOP-REAL 3,
                uf be FinSequence of F_Real,
                 p be FinSequence of 1-tuples_on REAL
      such that
A8:   y9 = Dir u & u is not zero & u = uf & p = N * uf & v = M2F p &
        v is not zero & (homography(N)).y9 = Dir v by ANPROJ_8:def 4;
      reconsider x9 = x as Element of ProjectiveSpace TOP-REAL 3
        by A5,A3,A6,FUNCT_1:3;
      reconsider z1 = 0,z2 = a,z3 = -a as Element of F_Real by XREAL_0:def 1;
A9:   N = <* <* z2,z1,z1 *> ,
             <* z1,z2,z1 *>,
             <* z1,z1,z3 *> *> by A1,PASCAL:def 3;
      reconsider ux = u`1,uy = u`2,uz = u`3 as Element of F_Real
        by XREAL_0:def 1;
      <* ux,uy,uz *> = uf by A8,EUCLID_5:3; then
A10:  p = <* <* z2 * ux + z1 * uy + z1 * uz *>,
             <* z1 * ux + z2 * uy + z1 * uz *>,
             <* z1 * ux + z1 * uy + z3 * uz *> *> &
      v = <* z2 * ux + z1 * uy + z1 * uz ,
          z1 * ux + z2 * uy + z1 * uz ,
          z1 * ux + z1 * uy + z3 * uz  *> by A8,A9,PASCAL:8;
      are_Prop u9,u by A7,A8,ANPROJ_1:22;
      then consider l be Real such that
A11:  l <> 0 and
A12:  u9 = l * u by ANPROJ_1:1;
A13:  u9.1 = l * u.1 & u9.2 = l * u.2 & u9.3 = l * u.3 by A12,RVSUM_1:44;
      reconsider w = |[ - u.1 * l, - u.2 * l, u.3 * l ]|
        as Element of TOP-REAL 3;
A15:  w is non zero
      proof
        assume w is zero;
        then u.1 = 0 & u.2 = 0 & u.3 = 0 by A11,FINSEQ_1:78,EUCLID_5:4;
        then u`1 = 0 & u`2 = 0 & u`3 = 0 by EUCLID_5:def 1,def 2,def 3;
        hence contradiction by A8,EUCLID_5:3,4;
      end;
A16:  (-1) * w`1 = (-1) * (-u.1 * l) & (-1) * w`2 = (-1) * (-u.2 * l) &
        (-1) * w`3 = (-1) * (u.3 * l) by EUCLID_5:2;
      then (-1) * w`1 = 1 * u.1 * l & (-1) * w`2 = 1 * u.2 * l &
        (-1) * w`3 = -1 * u.3 * l; then
A17:  (-1) * w`1 = u`1 * l & (-1) * w`2 = u`2 * l &
        (-1) * w`3 = -1 * u`3 * l by EUCLID_5:def 1,def 2,def 3;
      now
        thus -a / l <> 0 by A11;
        (-a / l) * w`1 = v`1 & (-a / l) * w`2 = v`2 &
          (-a / l) * w`3 = v`3
        proof
          thus (-a / l) * w`1
            = (a / l) * ((-1) * w`1)
           .= (a / l) * (u`1 * l) by A16,EUCLID_5:def 1
           .= a * u`1 by A11,XCMPLX_1:90
           .= v`1 by A10,EUCLID_5:2;
          thus (-a / l) * w`2
            = (a / l) * ((-1) * w`2)
            .= (a / l) * (u`2 * l) by A16,EUCLID_5:def 2
            .= a * u`2 by A11,XCMPLX_1:90
            .= v`2 by A10,EUCLID_5:2;
          thus (-a / l) * w`3
            = - (a / l) * (u`3 * l) by A17
           .= - a * u`3 by A11,XCMPLX_1:90
           .= v`3 by A10,EUCLID_5:2;
        end;
        then |[v`1,v`2,v`3]|
          = (-a / l) * |[w`1,w`2,w`3]| by EUCLID_5:8
         .= (-a / l) * w by EUCLID_5:3;
        hence v = (-a / l) * w by EUCLID_5:3;
      end;
      then are_Prop w,v by ANPROJ_1:1; then
A18:  Dir w = Dir v by ANPROJ_1:22,A15,A8;
A19:  (w.1)^2 + (w.2)^2 = 1^2 & w.3 = 1
      proof
        thus 1^2 = ((l * u`1) * (l * u.1)) + ((l * u.2) * (l * u.2))
           by EUCLID_5:def 1,A13,A7
         .= ((l * u`1) * (l * u`1)) + ((l * u.2) * (l * u.2)) by EUCLID_5:def 1
         .= ((l * u`1) * (l * u`1)) + ((l * u`2) * (l * u.2)) by EUCLID_5:def 2
         .= ((-1) * w`1) * ((-1) * w`1) + ((-1) * w`2) * ((-1) * w`2)
           by A17,EUCLID_5:def 2
         .= w`1 * w`1 + w`2 * w`2
         .= w.1 * w`1 + w`2 * w`2 by EUCLID_5:def 1
         .= w.1 * w.1 + w`2 * w`2 by EUCLID_5:def 1
         .= w.1 * w.1 + w.2 * w`2 by EUCLID_5:def 2
         .= (w.1)^2 + (w.2)^2 by EUCLID_5:def 2;
        thus w.3 = 1 by A13,A7;
      end;
      then |[w.1,w.2]| in circle(0,0,1) by BKMODEL1:14;
      then x9 is Element of absolute by A15,A18,A8,A5,A19,BKMODEL1:86;
      hence thesis;
    end;
    absolute c= homography(N).:absolute
    proof
      let x be object;
      assume x in absolute;
      then consider u be non zero Element of TOP-REAL 3 such that
A20:  (u.1)^2 + (u.2)^2 = 1 & u.3 = 1 & x = Dir u by BKMODEL1:89;
      reconsider w = |[ u.1 / a,u.2 / a, - u.3 / a ]| as Element of TOP-REAL 3;
A21:  w is non zero
      proof
        assume w is zero;
        then u.1 = 0 & u.2 = 0 & u.3 = 0 by FINSEQ_1:78,EUCLID_5:4;
        then u`1 = 0 & u`2 = 0 & u`3 = 0 by EUCLID_5:def 1,def 2,def 3;
        hence contradiction by EUCLID_5:3,4;
      end;
      then reconsider P = Dir w as Element of ProjectiveSpace TOP-REAL 3
        by ANPROJ_1:26;
      reconsider v = |[ -u.1,-u.2,u.3 ]| as Element of TOP-REAL 3;
A22:  (-a) * (u.1 / a) = - a * (u.1 /a)
                      .= - u.1 by XCMPLX_1:87;
A23:  (-a) * (u.2 / a) = - a * (u.2 /a)
                      .= - u.2 by XCMPLX_1:87;
A24:  (-a) * (- u.3 / a) = a * (u.3 /a)
                        .= u.3 by XCMPLX_1:87;
A25:  v is non zero by A20,FINSEQ_1:78,EUCLID_5:4;
      v = (-a) * w by A22,A23,A24,EUCLID_5:8;
      then are_Prop v,w by ANPROJ_1:1; then
A26:  P = Dir v by A21,A25,ANPROJ_1:22;
A27:  v.3 = 1 by A20;
      |[v.1,v.2]| in circle(0,0,1)
      proof
        (v.1)^2 + (v.2)^2 = 1^2 by A20;
        hence thesis by BKMODEL1:14;
      end;
      then reconsider P as Element of absolute by A26,A27,A25,BKMODEL1:86;
      now
        dom homography(N) = the carrier of ProjectiveSpace TOP-REAL 3
          by FUNCT_2:def 1;
        hence P in dom homography(N);
        consider u1,v1 be Element of TOP-REAL 3,
                    uf be FinSequence of F_Real,
                     p be FinSequence of 1-tuples_on REAL
        such that
A31:    P = Dir u1 & u1 is not zero & u1 = uf & p = N * uf & v1 = M2F p &
          v1 is not zero & homography(N).P = Dir v1 by ANPROJ_8:def 4;
        are_Prop u1,w by A21,A31,ANPROJ_1:22;
        then consider l be Real such that
A32:    l <> 0 and
A33:    u1 = l * w by ANPROJ_1:1;
        u1 = |[ l * (u.1 / a), l * (u.2 /a), l * (- u.3 / a)]|
          by A33,EUCLID_5:8;
        then
A34:    u1`1 = l * (u.1 / a) & u1`2 = l * (u.2 / a) & u1`3 = l * (- u.3 / a)
          by EUCLID_5:2;
        reconsider z1 = 0,z2 = a,z3 = -a as Element of F_Real by XREAL_0:def 1;
A35:    N = <* <* z2,z1,z1 *> ,
                 <* z1,z2,z1 *>,
                 <* z1,z1,z3 *> *> by A1,PASCAL:def 3;
        reconsider ux = u1`1,uy = u1`2,uz = u1`3 as Element of F_Real
          by XREAL_0:def 1;
A36:    a * (l * (u.1 / a)) = l * (a * (u.1 / a))
                           .= l * u.1 by XCMPLX_1:87;
A37:    a * (l * (u.2 / a)) = l * (a * (u.2 / a))
                           .= l * u.2 by XCMPLX_1:87;
A38:    (-a) * (l * (- u.3 / a)) = l * (a * (u.3 / a))
                                .= l * u.3 by XCMPLX_1:87;
        <* ux,uy,uz *> = uf by A31,EUCLID_5:3;
        then p = <* <* z2 * ux + z1 * uy + z1 * uz *>,
                    <* z1 * ux + z2 * uy + z1 * uz *>,
                    <* z1 * ux + z1 * uy + z3 * uz *> *> &
            v1 = <* z2 * ux + z1 * uy + z1 * uz ,
                    z1 * ux + z2 * uy + z1 * uz ,
                    z1 * ux + z1 * uy + z3 * uz  *> by A31,A35,PASCAL:8;
        then v1`1 = a * u1`1 & v1`2 = a * u1`2 & v1`3 = (-a) * u1`3
          by EUCLID_5:2;
        then v1`1 = l * u`1 & v1`2 = l * u`2 & v1`3 = l * u`3
          by EUCLID_5:def 1,def 2,def 3,A34,A36,A37,A38;
        then v1 = |[ l * u`1,l * u`2, l * u`3]| by EUCLID_5:3
               .= l * |[u`1,u`2,u`3]| by EUCLID_5:8
               .= l * u by EUCLID_5:3;
        then are_Prop u,v1 by A32,ANPROJ_1:1;
        hence x = homography(N).P by A20,A31,ANPROJ_1:22;
      end;
      hence thesis by FUNCT_1:def 6;
    end;
    hence thesis by A2;
  end;
