reserve i, x, I for set,
  A, B, M for ManySortedSet of I,
  f, f1 for Function;
reserve SF, SG for SubsetFamily of M;
reserve E, T for Element of Bool M;
reserve g, h for SetOp of M;
reserve S for 1-sorted;
reserve MS for many-sorted over S;

theorem Th38:
  for D being ClosureSystem of S for a being Element of Bool the
Sorts of D for f being SetOp of the Sorts of D st a in the Family of D & for x
  being Element of Bool the Sorts of D holds f.x = Cl x holds f.a = a
proof
  let D be ClosureSystem of S, a be Element of Bool the Sorts of D, f be SetOp
  of the Sorts of D such that
A1: a in the Family of D and
A2: for x being Element of Bool the Sorts of D holds f.x = Cl x;
  consider F being SubsetFamily of the Sorts of D such that
A3: Cl a = meet |:F:| and
A4: F = { X where X is Element of Bool the Sorts of D : a c=' X & X in
  the Family of D } by Def22;
A5: f.a = meet |:F:| by A2,A3;
  a in F by A1,A4;
  then
A6: f.a c= a by A5,Th21,MSSUBFAM:43;
  for Z1 being ManySortedSet of the carrier of S st Z1 in F holds a c=' Z1
  proof
    let Z1 be ManySortedSet of the carrier of S;
    assume Z1 in F;
    then ex b being Element of Bool the Sorts of D st Z1 = b & a c=' b & b in
    the Family of D by A4;
    hence thesis;
  end;
  then a c= f.a by A5,Th24;
  hence thesis by A6,PBOOLE:146;
end;
