
theorem Th37:
for R, S being RelStr st R,S are_isomorphic & R is Dickson & R is quasi_ordered
  holds S is quasi_ordered & S is Dickson
proof
  let R, S be RelStr such that
A1: R,S are_isomorphic and
A2: R is Dickson and
A3: R is quasi_ordered;
  set CRS = the carrier of S, IRS = the InternalRel of S;
  per cases;
  suppose R is not empty & S is not empty;
    then reconsider Re = R, Se = S as non empty RelStr;
    consider f being Function of Re,Se such that
A4: f is isomorphic by A1,WAYBEL_1:def 8;
A5: f is one-to-one by A4,WAYBEL_0:66;
A6: rng f = the carrier of Se by A4,WAYBEL_0:66;
A7: Re is reflexive by A3;
A8: Re is transitive by A3;
A9: Se is reflexive by A1,A7,WAYBEL20:15;
    Se is transitive by A1,A8,WAYBEL20:16;
    hence
A10: S is quasi_ordered by A9;
    now
      let t be sequence of Se;
      reconsider fi = f" as Function of the carrier of Se,
      the carrier of Re by A5,A6,FUNCT_2:25;
      deffunc F(Element of NAT) = fi.(t.$1);
      consider sr being sequence of  the carrier of Re such that
A11:  for x being Element of NAT holds sr.x = F(x) from FUNCT_2:sch 4;
      reconsider sr as sequence of Re;
      consider i,j being Nat such that
A12:  i < j and
A13:  sr.i <= sr.j by A2,Th28;
      take i,j;
A14:   i in NAT by ORDINAL1:def 12;
A15:   j in NAT by ORDINAL1:def 12;
      thus i < j by A12;
A16:  f.(sr.i) = f.(f".(t.i)) by A11,A14
        .= t.i by A5,A6,FUNCT_1:35;
      f.(sr.j) = f.(f".(t.j)) by A11,A15
        .= t.j by A5,A6,FUNCT_1:35;
      hence t.i <= t.j by A4,A13,A16,WAYBEL_0:66;
    end;
    then for N being non empty Subset of Se
    holds min-classes N is finite & min-classes N is non empty by A10,Th30;
    hence thesis by A10,Th31;
  end;
  suppose
A17: not(R is not empty & S is not empty);
A18: now per cases by A17;
      suppose
A19:    R is empty;
        ex f being Function of R,S st ( f is isomorphic) by A1,WAYBEL_1:def 8;
        hence S is empty by A19,WAYBEL_0:def 38;
      end;
      suppose S is empty;
        hence S is empty;
      end;
    end;
    then for x being object st x in CRS holds [x,x] in IRS;
    then
A20: IRS is_reflexive_in CRS;
    for x,y,z be object
    st x in CRS & y in CRS & z in CRS & [x,y] in IRS & [y,z] in IRS
    holds [x,z] in IRS by A18;
    then
A21: IRS is_transitive_in CRS;
A22: S is reflexive by A20;
    S is transitive by A21;
    hence S is quasi_ordered by A22;
    thus thesis by A18,Th35;
  end;
end;
