reserve x for object;
reserve x0,r,r1,r2,g,g1,g2,p,y0 for Real;
reserve n,m,k,l for Element of NAT;
reserve a,b,d for Real_Sequence;
reserve h,h1,h2 for non-zero 0-convergent Real_Sequence;
reserve c,c1 for constant Real_Sequence;
reserve A for open Subset of REAL;
reserve f,f1,f2 for PartFunc of REAL,REAL;
reserve L for LinearFunc;
reserve R for RestFunc;

theorem Th38:
  [#](REAL) c= dom f & f is_differentiable_on [#](REAL) & (for x0
  holds diff(f,x0) < 0) implies f|[#]REAL is decreasing & f is one-to-one
proof
  assume
 [#](REAL) c= dom f;
  assume that
A1: f is_differentiable_on [#](REAL) and
A2: for x0 holds diff(f,x0) < 0;
A3: now
    let r1,r2;
    assume that
A4: r1 in [#](REAL) /\ dom f and
A5: r2 in [#](REAL) /\ dom f and
A6: r1 < r2;
    set rx = max(r1,r2);
    set rn = min(r1,r2);
A7: r2 + 0 < rx + 1 by XREAL_1:8,XXREAL_0:25;
    rn - 1 < r2 - 0 by XREAL_1:15,XXREAL_0:17;
    then r2 in {g2: rn - 1 < g2 & g2 < rx + 1} by A7;
    then
A8: r2 in ].rn - 1, rx + 1.[ by RCOMP_1:def 2;
    r2 in dom f by A5,XBOOLE_0:def 4;
    then
A9: r2 in ].rn - 1, rx + 1.[ /\ dom f by A8,XBOOLE_0:def 4;
A10: for g1 holds g1 in ].rn - 1, rx + 1 .[ implies diff(f,g1) < 0 by A2;
    f is_differentiable_on ].rn - 1, rx + 1.[ by A1,FDIFF_1:26;
    then
A11: f|].rn-1,rx+1.[ is decreasing by A10,ROLLE:10;
A12: r1 + 0 < rx + 1 by XREAL_1:8,XXREAL_0:25;
    rn - 1 < r1 - 0 by XREAL_1:15,XXREAL_0:17;
    then r1 in {g1: rn - 1 < g1 & g1 < rx + 1} by A12;
    then
A13: r1 in ].rn - 1, rx + 1.[ by RCOMP_1:def 2;
    r1 in dom f by A4,XBOOLE_0:def 4;
    then r1 in ].rn - 1, rx + 1.[ /\ dom f by A13,XBOOLE_0:def 4;
    hence f.r2 < f.r1 by A6,A11,A9,RFUNCT_2:21;
  end;
  hence f|[#]REAL is decreasing by RFUNCT_2:21;
  now
    given r1,r2 being Element of REAL such that
A14: r1 in dom f and
A15: r2 in dom f and
A16: f.r1 = f.r2 and
A17: r1 <> r2;
A18: r2 in [#](REAL) /\ dom f by A15,XBOOLE_0:def 4;
A19: r1 in [#](REAL) /\ dom f by A14,XBOOLE_0:def 4;
    now
      per cases by A17,XXREAL_0:1;
      suppose
        r1 < r2;
        hence contradiction by A3,A16,A19,A18;
      end;
      suppose
        r2 < r1;
        hence contradiction by A3,A16,A19,A18;
      end;
    end;
    hence contradiction;
  end;
  hence thesis by PARTFUN1:8;
end;
