reserve x, y, X for set;
reserve E for non empty set;
reserve e for Element of E;
reserve u, u1, v, v1, v2, w, w9, w1, w2 for Element of E^omega;
reserve F for Subset of E^omega;
reserve i, k, l for Nat;
reserve TS for non empty transition-system over F;
reserve S, T for Subset of TS;
reserve SA for non empty semiautomaton over F;
reserve A for non empty automaton over F;
reserve p, q for Element of A;
reserve TS for non empty transition-system over Lex(E) \/ {<%>E};
reserve SA for non empty semiautomaton over Lex(E) \/ {<%>E};
reserve A for non empty automaton over Lex(E) \/ {<%>E};
reserve P for Subset of A;

theorem Th38:
  Lang(A) = Lang(_bool A)
proof
  set DA = _bool A;
A1: w in Lang(A) implies w in Lang(DA)
  proof
    assume w in Lang(A);
    then w-succ_of (the InitS of A, A) meets the FinalS of A by Th19;
    then ex x being object
st x in w-succ_of (the InitS of A, A) & x in the FinalS of A by
XBOOLE_0:3;
    then
A2: w-succ_of (the InitS of A, A) in the FinalS of DA by Th33;
    w-succ_of (the InitS of DA, DA) = { w-succ_of (the InitS of A, A) } by Th37
;
    then w-succ_of (the InitS of A, A) in w-succ_of (the InitS of DA, DA) by
TARSKI:def 1;
    then w-succ_of (the InitS of DA, DA) meets the FinalS of DA by A2,
XBOOLE_0:3;
    hence thesis by Th19;
  end;
  w in Lang(DA) implies w in Lang(A)
  proof
    assume w in Lang(DA);
    then w-succ_of (the InitS of DA, DA) meets the FinalS of DA by Th19;
    then consider x being object such that
A3: x in w-succ_of (the InitS of DA, DA) and
A4: x in the FinalS of DA by XBOOLE_0:3;
    w-succ_of (the InitS of _bool A, _bool A) = { w-succ_of (the InitS of
    A, A) } by Th37;
    then x = w-succ_of (the InitS of A, A) by A3,TARSKI:def 1;
    then w-succ_of (the InitS of A, A) meets the FinalS of A by A4,Th34;
    hence thesis by Th19;
  end;
  hence thesis by A1,SUBSET_1:3;
end;
