
theorem
  for n being Element of NAT, T being connected admissible TermOrder of
  n, L being Abelian add-associative right_complementable right_zeroed
  commutative associative well-unital distributive almost_left_invertible non
degenerated non empty doubleLoopStr, I being add-closed left-ideal non empty
  Subset of Polynom-Ring(n,L), G being Subset of Polynom-Ring(n,L), p being
Polynomial of n,L, q being non-zero Polynomial of n,L st p in G & q in G & p <>
  q & HT(q,T) divides HT(p,T) holds G is_Groebner_basis_of I,T implies G\{p}
  is_Groebner_basis_of I,T
proof
  let n be Element of NAT, T be connected admissible TermOrder of n, L be
  Abelian add-associative right_complementable right_zeroed commutative
  associative well-unital distributive almost_left_invertible non degenerated
  non empty doubleLoopStr, I be add-closed left-ideal non empty Subset of
Polynom-Ring(n,L), G be Subset of Polynom-Ring(n,L), p be Polynomial of n,L, q
  be non-zero Polynomial of n,L;
  assume that
A1: p in G and
A2: q in G and
A3: p <> q and
A4: HT(q,T) divides HT(p,T);
  reconsider GG = G as non empty Subset of Polynom-Ring(n,L) by A1;
  assume
A5: G is_Groebner_basis_of I,T;
  set G9 = G\{p};
A6: not q in {p} by A3,TARSKI:def 1;
  then q <> 0_(n,L) & q in G9 by A2,POLYNOM7:def 1,XBOOLE_0:def 5;
  then
A7: HT(q,T) in {HT(u,T) where u is Polynomial of n,L : u in G9 & u <> 0_(n,
  L)};
  GG c= GG-Ideal by IDEAL_1:def 14;
  then
A8: G c= I by A5;
  for f being Polynomial of n,L st f in I holds PolyRedRel(G,T) reduces f,
  0_(n,L) by A1,A5,Th24;
  then for f being non-zero Polynomial of n,L st f in I holds f
  is_reducible_wrt G,T by Th25;
  then
A9: for f being non-zero Polynomial of n,L st f in I holds f
  is_top_reducible_wrt G,T by A8,Th26;
  for b being bag of n st b in HT(I,T) ex b9 being bag of n st b9 in HT(
  G9,T) & b9 divides b
  proof
    let b be bag of n;
    assume b in HT(I,T);
    then consider bb being bag of n such that
A10: bb in HT(G,T) and
A11: bb divides b by A9,Th27;
    consider r being Polynomial of n,L such that
A12: bb = HT(r,T) and
A13: r in G and
A14: r <> 0_(n,L) by A10;
    now
      per cases;
      case
        r = p;
        hence thesis by A4,A7,A11,A12,Lm8;
      end;
      case
        r <> p;
        then not r in {p} by TARSKI:def 1;
        then r in G9 by A13,XBOOLE_0:def 5;
        then
        bb in {HT(u,T) where u is Polynomial of n,L : u in G9 & u <> 0_(n
        ,L)} by A12,A14;
        hence thesis by A11;
      end;
    end;
    hence thesis;
  end;
  then
A15: HT(I,T) c= multiples(HT(G9,T)) by Th28;
  G9 c= G by XBOOLE_1:36;
  then
A16: G9 c= I by A8;
  G9 <> {} by A2,A6,XBOOLE_0:def 5;
  hence thesis by A16,A15,Th29;
end;
