reserve X for set;
reserve G for Group;
reserve H for Subgroup of G;
reserve h,x,y for object;
reserve f for Endomorphism of G;
reserve phi for Automorphism of G;
reserve K for characteristic Subgroup of G;

theorem Th40:
  for G being Group
  for H being strict Subgroup of G
  holds H is characteristic Subgroup of G iff
  for phi being Automorphism of G holds Image(phi|H) is Subgroup of H
proof
  let G be Group;
  let H be strict Subgroup of G;
  thus H is characteristic Subgroup of G implies
       (for phi being Automorphism of G holds Image(phi|H) is Subgroup of H)
  proof
    assume B1: H is characteristic Subgroup of G;
    let phi be Automorphism of G;
    Image(phi|H) = H & H is Subgroup of H by B1,GROUP_2:54,Def3;
    hence Image(phi|H) is Subgroup of H;
  end;
  thus (for phi being Automorphism of G holds Image(phi|H) is Subgroup of H)
       implies H is characteristic Subgroup of G
  proof
    assume A1: for phi being Automorphism of G
    holds Image(phi|H) is Subgroup of H;
    A2: for phi being Automorphism of G holds H is Subgroup of Image(phi|H)
    proof
      let phi be Automorphism of G;
      consider psi being Automorphism of G such that
      B1: psi = phi" and
      B2: Image(phi|Image(psi|H)) is Subgroup of Image(phi|H) by A1,Th16;
      consider psi2 being Automorphism of G such that
      B3: psi2 = phi" and
      B4: the multMagma of H = Image(phi|Image(psi2|H)) by Th17;
      thus H is Subgroup of Image(phi|H) by B1,B2,B3,B4;
    end;
    for phi being Automorphism of G holds H = Image(phi|H)
    proof
      let phi be Automorphism of G;
      H is Subgroup of Image(phi|H) & Image(phi|H) is Subgroup of H
      by A1,A2;
      hence H = Image(phi|H) by GROUP_2:55;
    end;
    hence H is characteristic Subgroup of G by Def3;
  end;
end;
