reserve i, I for set,
  f, g, h for Function,
  s for ManySortedSet of I;
reserve G1, G2, G3 for non empty multMagma,
  x1, x2 for Element of G1,
  y1, y2 for Element of G2,
  z1, z2 for Element of G3;
reserve G1, G2, G3 for Group-like non empty multMagma;
reserve G1, G2, G3 for Group,
  x for Element of G1,
  y for Element of G2,
  z for Element of G3;

theorem Th38:
  for f being Homomorphism of G1, product <*G1*> st
    for x being Element of G1 holds f.x = <*x*> holds f is bijective
proof
  let f be Homomorphism of G1, product <*G1*> such that
A1: for x being Element of G1 holds f.x = <*x*>;
A2: dom f = the carrier of G1 by FUNCT_2:def 1;
A3: rng f = the carrier of product <*G1*>
  proof
    thus rng f c= the carrier of product <*G1*>;
    let x be object;
    assume x in the carrier of product <*G1*>;
    then reconsider a = x as Element of product <*G1*>;
A4: 1 in {1} by TARSKI:def 1;
    then
A5: ex R being 1-sorted st R = <*G1*>.1 & (Carrier <*G1*>).1 = the
    carrier of R by PRALG_1:def 15;
    a in the carrier of product <*G1*>;
    then
A6: a in product Carrier <*G1*> by Def2;
    then
A7: dom a = dom Carrier <*G1*> by CARD_3:9;
    then
A8: dom a = {1} by PARTFUN1:def 2;
    then a.1 in (Carrier <*G1*>).1 by A6,A7,A4,CARD_3:9;
    then reconsider b = a.1 as Element of G1 by A5;
    f.b = <*b*> by A1
      .= x by A8,FINSEQ_1:2,def 8;
    hence thesis by A2,FUNCT_1:def 3;
  end;
  f is one-to-one
  proof
    let m, n be object;
    assume that
A9: m in dom f and
A10: n in dom f and
A11: f.m = f.n;
    reconsider m1 = m, n1 = n as Element of G1 by A9,A10;
    <*m1*> = f.m1 by A1
      .= <*n1*> by A1,A11;
    hence thesis by FINSEQ_1:76;
  end;
  hence thesis by A3,GROUP_6:60;
end;
