reserve i, i1, i2, j, k for Nat,
  r, s for Real;
reserve D for non empty set,
  f1 for FinSequence of D;

theorem Th38:
  for f being non constant standard special_circular_sequence,
      i2 st 1<=i2 & i2+1<len f holds f/^i2 is being_S-Seq
proof
  let f be non constant standard special_circular_sequence,i2;
  assume that
A1: 1<=i2 and
A2: i2+1<len f;
A3: i2<len f by A2,NAT_1:13;
  for i,j be Nat st i+1 < j holds LSeg(f/^i2,i) misses LSeg(f/^i2,j)
  proof
    let i,j be Nat;
    assume
A4: i+1 < j;
    then
A5: i<j by NAT_1:13;
    now
      per cases;
      case
A6:     1<=i & j<len (f/^i2);
        then 1<j by A5,XXREAL_0:2;
        then LSeg(f/^i2,j)=LSeg(f,i2+j) by A3,SPPOL_2:4;
        then
A7:     LSeg(f/^i2,i) /\ LSeg(f/^i2,j) = LSeg(f,i2+i) /\ LSeg(f,i2+j) by A3,A6,
SPPOL_2:4;
        i2+(i+1)<i2+j by A4,XREAL_1:6;
        then
A8:     i2+i+1<i2+j;
        1+1<=i2+i by A1,A6,XREAL_1:7;
        then
A9:     1<i2+i by XXREAL_0:2;
        j<len f-i2 by A3,A6,RFINSEQ:def 1;
        then j+i2<len f-i2+i2 by XREAL_1:6;
        then LSeg(f,i2+i) misses LSeg(f,i2+j) by A8,A9,GOBOARD5:def 4;
        then LSeg(f,i2+i) /\ LSeg(f,i2+j) = {} by XBOOLE_0:def 7;
        hence thesis by A7,XBOOLE_0:def 7;
      end;
      case
A10:    1>i or j>=len (f/^i2);
        now
          per cases by A10;
          case
            1>i;
            then LSeg(f/^i2,i)={} by TOPREAL1:def 3;
            then LSeg(f/^i2,i) /\ LSeg(f/^i2,j) = {};
            hence thesis by XBOOLE_0:def 7;
          end;
          case
            j>=len (f/^i2);
            then j+1>len (f/^i2) by NAT_1:13;
            then LSeg(f/^i2,j)={} by TOPREAL1:def 3;
            then LSeg(f/^i2,i) /\ LSeg(f/^i2,j) = {};
            hence thesis by XBOOLE_0:def 7;
          end;
        end;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
  then
A11: f/^i2 is s.n.c. by TOPREAL1:def 7;
A12: len (f/^i2)=len f-i2 by A3,RFINSEQ:def 1;
  for n1,n2 being Nat st 1<=n1 & n1<=len (f/^i2) & 1<=n2 & n2
  <=len (f/^i2) &((f/^i2).n1=(f/^i2).n2 or (f/^i2)/.n1=(f/^i2)/.n2) holds n1=n2
  proof
    let n1,n2 be Nat;
    assume that
A13: 1<=n1 and
A14: n1<=len (f/^i2) and
A15: 1<=n2 and
A16: n2<=len (f/^i2) and
A17: (f/^i2).n1=(f/^i2).n2 or (f/^i2)/.n1=(f/^i2)/.n2;
A18: n2 in dom (f/^i2) by A15,A16,FINSEQ_3:25;
A19: n1 in dom (f/^i2) by A13,A14,FINSEQ_3:25;
    now
      per cases by XXREAL_0:1;
      case
        n1<n2;
        then
A20:    i2+n1<i2+n2 by XREAL_1:6;
A21:    1<i2+1 by A1,NAT_1:13;
        i2+1<=i2+n1 by A13,XREAL_1:6;
        then
A22:    1<i2+n1 by A21,XXREAL_0:2;
        n2+i2<=len f-i2+i2 by A12,A16,XREAL_1:6;
        then
A23:    f/.(i2+n1)<>f/.(i2+n2) by A22,A20,GOBOARD7:37;
A24:    (f/^i2)/.n1=f/.(i2+n1) by A19,FINSEQ_5:27;
A25:    (f/^i2)/.n2=f/.(i2+n2) by A18,FINSEQ_5:27;
        (f/^i2)/.n1=(f/^i2).(n1) by A13,A14,FINSEQ_4:15;
        hence contradiction by A15,A16,A17,A23,A24,A25,FINSEQ_4:15;
      end;
      case
        n1=n2;
        hence thesis;
      end;
      case
        n2<n1;
        then
A26:    i2+n2<i2+n1 by XREAL_1:6;
A27:    1<i2+1 by A1,NAT_1:13;
        i2+1<=i2+n2 by A15,XREAL_1:6;
        then
A28:    1<i2+n2 by A27,XXREAL_0:2;
        n1+i2<=len f-i2+i2 by A12,A14,XREAL_1:6;
        then
A29:    f/.(i2+n2)<>f/.(i2+n1) by A28,A26,GOBOARD7:37;
        n2 in dom (f/^i2) by A15,A16,FINSEQ_3:25;
        then
A30:    (f/^i2)/.n2=f/.(i2+n2) by FINSEQ_5:27;
        n1 in dom (f/^i2) by A13,A14,FINSEQ_3:25;
        then
A31:    (f/^i2)/.n1=f/.(i2+n1) by FINSEQ_5:27;
        (f/^i2)/.n2=(f/^i2).n2 by A15,A16,FINSEQ_4:15;
        hence contradiction by A13,A14,A17,A29,A30,A31,FINSEQ_4:15;
      end;
    end;
    hence thesis;
  end;
  then
A32: f/^i2 is one-to-one by Th36;
  i2+1-i2<len f-i2 by A2,XREAL_1:9;
  then 1+1<=len (f/^i2) by A12,NAT_1:13;
  hence thesis by A11,A32,TOPREAL1:def 8;
end;
