
theorem Th38:
  for X be Banach_Algebra holds for x,y,z being Element of X
   for a,b be Real
  holds x+y = y+x & (x+y)+z = x+(y+z) & x+(0.X) = x & (ex t being
Element of X st x+t= 0.X) & (x*y)*z = x*(y*z) & 1*x=x & 0*x=0.X & a*0.X =0.X&
   (-1)*x=-x & x*(1.X) = x & (1.X)*x = x & x*(y+z) = x*y + x*z &
   (y+z)*x = y*x + z*
x & a*(x*y) = (a*x)*y & a*(x+y) = a*x + a*y & (a+b)*x = a*x + b*x & (a*b)*x = a
*(b*x) & (a*b)*(x*y)=(a*x)*(b*y) & a*(x*y)=x*(a*y) & 0.X * x = 0.X & x*0.X =0.X
& x*(y-z) = x*y-x*z & (y-z)*x = y*x-z*x & x+y-z = x+(y-z) & x-y+z = x-(y-z) & x
-y-z = x-(y+z) & x+y=(x-z)+(z+y) & x-y=(x-z)+(z-y) & x=(x-y)+y & x=y-(y-x) & (
||.x.|| = 0 iff x = 0.X ) & ||.a * x.|| = |.a.| * ||.x.|| & ||.x + y.|| <= ||.
  x.|| + ||.y.|| & ||. x*y .|| <= ||.x.|| * ||.y.|| & ||. 1.X .|| = 1 & X is
  complete
proof
  let X be Banach_Algebra;
  let x,y,z being Element of X;
  let a,b be Real;
  thus x+y = y+x;
  thus (x+y)+z = x+(y+z) by RLVECT_1:def 3;
  thus x+(0.X) = x by RLVECT_1:def 4;
  thus ex t being Element of X st x+t=0.X by ALGSTR_0:def 11;
  thus (x*y)*z = x*(y*z) by GROUP_1:def 3;
  thus 1*x = x by RLVECT_1:def 8;
  thus 0*x = 0.X by RLVECT_1:10;
  thus a*0.X =0.X by RLVECT_1:10;
  thus (-1)*x = -x by RLVECT_1:16;
  thus x*(1.X) = x & (1.X)*x= x & x*(y+z) = x*y + x*z & (y+z)*x = y*x + z*x &
a*(x*y) = (a*x)*y & a*(x+y) = a*x + a*y & (a+b)*x = a*x + b*x & (a*b)*x = a*(b*
  x) by FUNCSDOM:def 9,RLVECT_1:def 5,def 6,def 7,VECTSP_1:def 2,def 3,def 4
,def 8;
  thus (a*b)*(x*y) =a*(b*(x*y)) by RLVECT_1:def 7
    .=a*(x*(b*y) ) by LOPBAN_2:def 11
    .=(a*x)*(b*y) by FUNCSDOM:def 9;
  thus a*(x*y)=x*(a*y) by LOPBAN_2:def 11;
A1: x*(y-z)+x*z =x*((y-z)+z) by VECTSP_1:def 2
    .=x*(y-(z-z)) by RLVECT_1:29
    .=x*(y-0.X) by RLVECT_1:15
    .=x*y by RLVECT_1:13;
  x*0.X =x*(0.X+0.X) by RLVECT_1:def 4
    .=x*0.X + x*0.X by VECTSP_1:def 2;
  then 0.X = x*0.X + x*0.X-x* 0.X by RLVECT_1:15;
  then 0.X = x*0.X + (x*0.X-x* 0.X) by RLVECT_1:def 3;
  then
A2: 0.X = x*0.X + 0.X by RLVECT_1:15;
  0.X*x =(0.X+0.X)*x by RLVECT_1:def 4
    .=0.X*x + 0.X*x by VECTSP_1:def 3;
  then 0.X = 0.X*x + 0.X*x-0.X * x by RLVECT_1:15;
  then 0.X = 0.X*x + (0.X*x-0.X * x) by RLVECT_1:def 3;
  then 0.X = 0.X*x + 0.X by RLVECT_1:15;
  hence 0.X * x = 0.X & x*0.X =0.X by A2,RLVECT_1:def 4;
  thus x*(y-z) =x*(y-z)+0.X by RLVECT_1:4
    .=x*(y-z)+(x*z-x*z) by RLVECT_1:15
    .=x*y-x*z by A1,RLVECT_1:def 3;
A3: (y-z)*x+z*x =((y-z)+z)*x by VECTSP_1:def 3
    .=(y-(z-z))*x by RLVECT_1:29
    .=(y-0.X)*x by RLVECT_1:15
    .=y*x by RLVECT_1:13;
  thus (y-z)*x =(y-z)*x+0.X by RLVECT_1:4
    .=(y-z)*x+(z*x-z*x) by RLVECT_1:15
    .=y*x-z*x by A3,RLVECT_1:def 3;
  thus x+y-z = x+(y-z) by RLVECT_1:def 3;
  thus x-y+z = x-(y-z) by RLVECT_1:29;
  thus x-y-z = x-(y+z) by RLVECT_1:27;
  thus (x-z)+(z+y)=(x-z)+z+y by RLVECT_1:def 3
    .=x-(z-z)+y by RLVECT_1:29
    .=x-0.X + y by RLVECT_1:15
    .=x+y by RLVECT_1:13;
  thus (x-z)+(z-y) =x-z+z-y by RLVECT_1:def 3
    .=x-(z-z)-y by RLVECT_1:29
    .=x-0.X -y by RLVECT_1:15
    .=x-y by RLVECT_1:13;
  thus (x-y)+y=x-(y-y) by RLVECT_1:29
    .=x-0.X by RLVECT_1:15
    .=x by RLVECT_1:13;
  thus y-(y-x)=y-y + x by RLVECT_1:29
    .=0.X + x by RLVECT_1:15
    .=x by RLVECT_1:4;
  thus ( ||.x.|| = 0 iff x = 0.X ) & ||.a * x.|| = |.a.| * ||.x.|| & ||.x + y
.|| <= ||.x.|| + ||.y.|| & ||. x*y .|| <= ||.x.|| * ||.y.|| by LOPBAN_2:def 9
,NORMSP_0:def 5,NORMSP_1:def 1;
  thus thesis by LOPBAN_2:def 10;
end;
