reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);
reserve D for non empty set,
  bD for FinSequence of D,
  b,f,g for FinSequence of K,
  MD for Matrix of D;

theorem Th38:
  X in Solutions_of(A9,B9) implies X in Solutions_of(RLine(A9,i,a*
  Line(A9,i)),RLine(B9,i,a*Line(B9,i)))
proof
  set LA=Line(A9,i);
  set LB=Line(B9,i);
  set RA=RLine(A9,i,a*LA);
  set RB=RLine(B9,i,a*LB);
A1: Indices RB=Indices B9 by MATRIX_0:26;
A2: len (a*LB)=len LB & len LB=width B9 by CARD_1:def 7,MATRIXR1:16;
  then
A3: width RB=width B9 by MATRIX11:def 3;
A4: len (a*LA)=len LA & len LA= width A9 by CARD_1:def 7,MATRIXR1:16;
  then
A5: len RA=len A9 by MATRIX11:def 3;
  assume
A6: X in Solutions_of(A9,B9);
  then consider X1 be Matrix of K such that
A7: X = X1 and
A8: len X1 = width A9 and
A9: width X1 = width B9 and
A10: A9 * X1 = B9;
  set RX=RA*X1;
A11: width RA=width A9 by A4,MATRIX11:def 3;
  then
A12: len RX=len RA & width RX=width X1 by A8,MATRIX_3:def 4;
A13: len A9=len B9 by A6,Th33;
  then dom B9=Seg len RA by A5,FINSEQ_1:def 3;
  then
A14: Indices RX=Indices B9 by A9,A12,FINSEQ_1:def 3;
A15: now
    len B9=m by MATRIX_0:def 2;
    then
A16: dom B9=Seg m by FINSEQ_1:def 3;
    let j,k such that
A17: [j,k] in Indices RB;
A18: j in dom B9 by A1,A17,ZFMISC_1:87;
A19: k in Seg width B9 by A1,A17,ZFMISC_1:87;
    then B9*(i,k)=LB.k by MATRIX_0:def 7;
    then reconsider LBk=LB.k as Element of K;
A20: B9*(j,k)= Line(A9,j) "*" Col(X1,k) by A8,A10,A1,A17,MATRIX_3:def 4;
    now
      per cases;
      suppose
A21:    j=i;
        then Line(RA,i)=a*LA by A4,A18,A16,MATRIX11:28;
        hence RX*(j,k) = (a*LA)"*"Col(X1,k) by A8,A11,A14,A1,A17,A21,
MATRIX_3:def 4
          .= Sum(a*mlt(LA,Col(X1,k))) by A8,FVSUM_1:68
          .= a*Sum(mlt(LA,Col(X1,k))) by FVSUM_1:73
          .= a*LBk by A19,A20,A21,MATRIX_0:def 7
          .= (a*LB).k by A19,FVSUM_1:51
          .= RB*(j,k) by A2,A1,A17,A21,MATRIX11:def 3;
      end;
      suppose
A22:    j<>i;
        then Line(RA,j)=Line(A9,j) by A18,A16,MATRIX11:28;
        hence RX*(j,k) = Line(A9,j)"*"Col(X1,k) by A8,A11,A14,A1,A17,
MATRIX_3:def 4
          .= B9*(j,k) by A8,A10,A1,A17,MATRIX_3:def 4
          .= RB*(j,k) by A2,A1,A17,A22,MATRIX11:def 3;
      end;
    end;
    hence RB*(j,k) = RX*(j,k);
  end;
  len RB=len B9 by A2,MATRIX11:def 3;
  then RX=RB by A9,A13,A5,A3,A12,A15,MATRIX_0:21;
  hence thesis by A7,A8,A9,A11,A3;
end;
