
theorem
for F be without-infty FinSequence of ExtREAL, G be ExtREAL_sequence
 st (for i be Nat holds F.i = G.i)
 holds G is summable & Sum F = Sum G
proof
   let F be without-infty FinSequence of ExtREAL, G be ExtREAL_sequence;
   assume A1: for i be Nat holds F.i = G.i; then
A2:Sum(F|len F) = (Partial_Sums G).(len F) by Th35;

   defpred P[Nat] means Sum F = (Partial_Sums G).(len F + $1);

B1:P[0] by A2,FINSEQ_1:58;
B2:for k be Nat st P[k] holds P[k+1]
   proof
    let k be Nat;
    assume A3: P[k];
    len F < len F + (k+1) by NAT_1:11,19; then
    not len F + k+1 in dom F by FINSEQ_3:25; then
    F.(len F + k+1) = 0 by FUNCT_1:def 2; then
A4: G.(len F + k+1) = 0 by A1;

    (Partial_Sums G).(len F + (k+1))
     = (Partial_Sums G).(len F + k) + G.(len F + k + 1) by MESFUNC9:def 1
    .= (Partial_Sums G).(len F + k) by A4,XXREAL_3:4;
    hence P[k+1] by A3;
   end;
A5:for k be Nat holds P[k] from NAT_1:sch 2(B1,B2);

   hereby
    per cases by XXREAL_0:14;
    suppose Sum F in REAL; then
     reconsider r = Sum F as Real;
B1:  for p be Real st 0<p ex n be Nat st for m be Nat st n<=m
      holds |.(Partial_Sums G).m - r qua ExtReal .| < p
     proof
      let p be Real;
      assume A6: 0 < p;
      take n = len F;
      now let m be Nat;
       assume len F <= m; then
       reconsider k = m - n as Nat by NAT_1:21;
       m = n + k; then
       (Partial_Sums G).m = Sum F by A5;
       hence |. (Partial_Sums G).m - r qua ExtReal .| < p
         by A6,XXREAL_3:7,EXTREAL1:16;
      end;
      hence thesis;
     end; then
B2:  Partial_Sums G is convergent_to_finite_number by MESFUNC5:def 8;
     hence G is summable by MESFUNC9:def 2;
     lim Partial_Sums G = Sum F by B1,B2,MESFUNC5:def 12;
     hence Sum F = Sum G by MESFUNC9:def 3;
   end;
    suppose A7: Sum F = +infty;
     now let g be Real;
      assume 0 < g;
      thus ex n be Nat st
       for m be Nat st n <= m holds g <= (Partial_Sums G).m
      proof
       take n = len F;
       hereby let m be Nat;
        assume n <= m; then
        reconsider k = m - n as Nat by NAT_1:21;
        m = n + k; then
        (Partial_Sums G).m = +infty by A5,A7;
        hence g <= (Partial_Sums G).m by XXREAL_0:3;
       end;
      end;
     end; then
B5:  Partial_Sums G is convergent_to_+infty by MESFUNC5:def 9;
     hence G is summable by MESFUNC9:def 2;
     lim Partial_Sums G = Sum F by A7,B5,MESFUNC5:def 12;
     hence Sum F = Sum G by MESFUNC9:def 3;
    end;
    suppose A8: Sum F = -infty;
     now let g be Real;
      assume g < 0;
      thus ex n be Nat st
       for m be Nat st n <= m holds (Partial_Sums G).m <= g
      proof
       take n = len F;
       hereby let m be Nat;
        assume n <= m; then
        reconsider k = m - n as Nat by NAT_1:21;
        m = n + k; then
        (Partial_Sums G).m = -infty by A5,A8;
        hence (Partial_Sums G).m <= g by XXREAL_0:5;
       end;
      end;
     end; then
B8:  Partial_Sums G is convergent_to_-infty by MESFUNC5:def 10;
     hence G is summable by MESFUNC9:def 2;
     lim Partial_Sums G = Sum F by A8,B8,MESFUNC5:def 12;
     hence Sum F = Sum G by MESFUNC9:def 3;
    end;
   end;
end;
