reserve E, F, G,S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem Th39:
  for i be Nat,
      S,E,F,G be RealNormSpace,
      Z be Subset of S,
      B be Lipschitzian BilinearOperator of E,F,G,
      u be PartFunc of S,E,
      v be PartFunc of S,F,
      w be PartFunc of S,[:E,F:],
      W be PartFunc of S,G
  st W = B * w & w = <:u,v:>
   & u is_differentiable_on i,Z
   & v is_differentiable_on i,Z
  holds W is_differentiable_on i,Z
proof
  defpred P[Nat] means
  for S,E,F,G be RealNormSpace,
      Z be Subset of S,
      B be Lipschitzian BilinearOperator of E,F,G,
      u be PartFunc of S,E,
      v be PartFunc of S,F,
      w be PartFunc of S,[:E,F:],
      W be PartFunc of S,G
   st W = B * w & w = <:u,v:>
    & u is_differentiable_on $1,Z
    & v is_differentiable_on $1,Z
  holds W is_differentiable_on $1,Z;

  A1: P[0]
  proof
    let S,E,F,G be RealNormSpace,
        Z be Subset of S,
        B be Lipschitzian BilinearOperator of E,F,G,
        u be PartFunc of S,E,
        v be PartFunc of S,F,
        w be PartFunc of S,[:E,F:],
        W be PartFunc of S,G;
    assume
    A2: W = B * w & w = <:u,v:>
      & u is_differentiable_on 0,Z
      & v is_differentiable_on 0,Z;

    dom B = [#][:E,F:] by FUNCT_2:def 1;
    then rng w c= dom B;
    then A3: dom W = dom w by A2,RELAT_1:27;
    dom w = (dom u ) /\ (dom v ) by A2,FUNCT_3:def 7;
    hence W is_differentiable_on 0,Z by A2,A3,XBOOLE_1:19;
  end;

  A4:for i be Nat st P[i] holds P[i+1]
  proof
    let i be Nat;
    assume A5: P[i];
    let S,E,F,G be RealNormSpace,
        Z be Subset of S,
        B be Lipschitzian BilinearOperator of E,F,G,
        u be PartFunc of S,E,
        v be PartFunc of S,F,
        w be PartFunc of S,[:E,F:],
        W be PartFunc of S,G;
    assume
    A6: W = B * w & w = <:u,v:>
      & u is_differentiable_on i+1,Z
      & v is_differentiable_on i+1,Z;

    0 <= i by NAT_1:2;
    then u is_differentiable_on 0+1,Z
       & v is_differentiable_on 0+1,Z by A6,NDIFF_6:17,XREAL_1:7;
    then
    A7: u|Z is_differentiable_on Z
      & v|Z is_differentiable_on Z by NDIFF_6:15;

    A8: u is_differentiable_on Z by A6,A7;
    A9: v is_differentiable_on Z by A6,A7;

    A10: W is_differentiable_on Z
      & for x be Point of S
         st x in Z
        holds
          for ds be Point of S
          holds
            ((W`|Z)/.x).ds
          = B.(((u`|Z)/.x).ds, v/.x)
          + B.(u/.x, ((v`|Z)/.x).ds)
          by A6,A8,A9,Th35;

    A11: u`|Z is_differentiable_on i,Z by A6,Th36;
    A12: v`|Z is_differentiable_on i,Z by A6,Th36;

    set V10 = the Point of E;
    set V20 = the Point of F;

    reconsider BP = B
      as Point of R_NormSpace_of_BoundedBilinearOperators(E,F,G)
        by LOPBAN_9:def 4;

    defpred P1[ object , object ] means
    ex V2 be Point of F
    st V2 = $1 & $2 = B * reproj1([V10,V2]);

    A13: for x be object st x in the carrier of F
          holds
            ex y be object
            st y in the carrier of R_NormSpace_of_BoundedLinearOperators(E,G)
            & P1[x,y]
    proof
      let x be object;
      assume x in the carrier of F;
      then reconsider V2 = x as Point of F;
      A14: B * reproj1([V10,V2]) is Lipschitzian LinearOperator of E,G
        by NDIFF12:2;
      take y = B * reproj1([V10,V2]);
      thus thesis by A14,LOPBAN_1:def 9;
    end;

    consider B2 be Function
      of the carrier of F,
         the carrier of R_NormSpace_of_BoundedLinearOperators(E,G)
    such that
    A15: for x be object st x in the carrier of F
         holds P1[x,B2.x] from FUNCT_2:sch 1(A13);

    A16: for V2 be Point of F holds B2.V2 = B * reproj1([V10,V2])
    proof
      let V2 be Point of F;
      ex V be Point of F
      st V = V2 & B2.V2 = B * reproj1([V10,V]) by A15;
      hence B2.V2 = B * reproj1([V10,V2]);
    end;

    defpred P2[object, object] means
    ex V1 be Point of E
    st V1 = $1 & $2 = B * reproj2([V1,V20]);

    A17: for x be object st x in the carrier of E
         holds
         ex y be object
         st y in the carrier of R_NormSpace_of_BoundedLinearOperators(F,G)
          & P2[x,y]
    proof
      let x be object;
      assume x in the carrier of E;
      then reconsider V1 = x as Point of E;
      A18: B * reproj2([V1,V20]) is Lipschitzian LinearOperator of F,G
        by NDIFF12:2;
      take y = B * reproj2([V1,V20]);
      thus thesis by A18,LOPBAN_1:def 9;
    end;

    consider B1 be Function
      of the carrier of E,
         the carrier of R_NormSpace_of_BoundedLinearOperators(F,G)
    such that
    A19: for x be object st x in the carrier of E
         holds P2[x,B1.x] from FUNCT_2:sch 1(A17);

    A20: for V1 be Point of E holds B1.V1 = B * reproj2([V1,V20])
    proof
      let V1 be Point of E;
      ex V be Point of E
      st V1 = V & B1.V1 = B * reproj2([V,V20]) by A19;
      hence B1.V1 = B * reproj2([V1,V20]);
    end;

    for x, y be Element of F holds B2.(x + y) = B2.x + B2.y
    proof
      let x, y be Element of F;
      A21: B2.y = B * reproj1([V10,y]) by A16;

      set f = B * reproj1([V10,x]);
      set g = B * reproj1([V10,y]);
      set h = B * reproj1([V10,x+y]);

      for s be VECTOR of E holds B2.(x+y).s = (B2.x).s + (B2.y).s
      proof
        let s be VECTOR of E;
        thus B2.(x+y).s
         = h.s by A16
        .= B.((reproj1 [V10,x+y]).s) by FUNCT_2:15
        .= B.([s,[V10,x+y]`2]) by NDIFF_7:def 1
        .= B.(s,x+y) by BINOP_1:def 1
        .= B.(s,x) + B.(s,y) by LOPBAN_8:12
        .= B.[s,x] + B.(s,y) by BINOP_1:def 1
        .= B.[s,[V10,x]`2] + B.[s,y] by BINOP_1:def 1
        .= B.((reproj1 [V10,x]).s) + B.[s,[V10,y]`2] by NDIFF_7:def 1
        .= B.((reproj1 [V10,x]).s) + B.((reproj1 [V10,y]).s) by NDIFF_7:def 1
        .= f.s + B.((reproj1 [V10,y]).s) by FUNCT_2:15
        .= f.s + g.s by FUNCT_2:15
        .= (B2.x).s + (B2.y).s by A16,A21;
      end;
      hence B2.(x+y) = B2.x + B2.y by LOPBAN_1:35;
    end;
    then
    A22: B2 is additive;

    for x be VECTOR of F, a be Real holds B2.(a*x) = a * B2.x
    proof
      let x be VECTOR of F, a be Real;

      set f = B * reproj1([V10,x]);
      set g = B * reproj1([V10,a*x]);

      for s be VECTOR of E holds (B2.(a*x)).s = a * (B2.x).s
      proof
        let s be VECTOR of E;
        thus (B2.(a*x)).s
         = g.s by A16
        .= B.((reproj1 [V10,a*x]).s) by FUNCT_2:15
        .= B.([s,[V10,a*x]`2]) by NDIFF_7:def 1
        .= B.(s,a*x) by BINOP_1:def 1
        .= a * B.(s,x) by LOPBAN_8:12
        .= a * B.[s,[V10,x]`2] by BINOP_1:def 1
        .= a * B.((reproj1 [V10,x]).s) by NDIFF_7:def 1
        .= a * f.s by FUNCT_2:15
        .= a * (B2.x).s by A16;
      end;
      hence B2.(a*x) = a * B2.x by LOPBAN_1:36;
    end;
    then reconsider B2 as LinearOperator
      of F,R_NormSpace_of_BoundedLinearOperators(E,G) by A22,LOPBAN_1:def 5;

    for x, y be Element of E holds B1.(x + y) = B1.x + B1.y
    proof
      let x, y be Element of E;
      A23: B1.y = B * reproj2([y,V20]) by A20;

      set f = B * reproj2([x,V20]);
      set g = B * reproj2([y,V20]);
      set h = B * reproj2([x+y,V20]);

      for s be VECTOR of F holds (B1.(x+y)).s = (B1.x).s + (B1.y).s
      proof
        let s be VECTOR of F;

        thus (B1.(x+y)).s
         = h.s by A20
        .= B.((reproj2 [x+y,V20]).s) by FUNCT_2:15
        .= B.([[x+y,V20]`1,s]) by NDIFF_7:def 2
        .= B.(x+y,s) by BINOP_1:def 1
        .= B.(x,s) + B.(y,s) by LOPBAN_8:12
        .= B.[x,s] + B.(y,s) by BINOP_1:def 1
        .= B.[[x,V20]`1,s] + B.[y,s] by BINOP_1:def 1
        .= B.((reproj2 [x,V20]).s) + B.[[y,V20]`1,s ] by NDIFF_7:def 2
        .= B.((reproj2 [x,V20]).s) + B.((reproj2 [y,V20]).s) by NDIFF_7:def 2
        .= f.s + B.((reproj2 [y,V20]).s) by FUNCT_2:15
        .= f.s + g.s by FUNCT_2:15
        .= (B1.x).s + (B1.y).s by A20,A23;
      end;
      hence B1.(x+y) = B1.x + B1.y by LOPBAN_1:35;
    end;
    then A24: B1 is additive;

    for x be VECTOR of E, a be Real holds B1.(a*x) = a * B1.x
    proof
      let x be VECTOR of E, a be Real;

      set f = B * reproj2([x,V20]);
      set g = B * reproj2([a*x,V20]);

      for s be VECTOR of F holds (B1.(a*x)).s = a * (B1.x).s
      proof
        let s be VECTOR of F;

        thus (B1.(a*x)).s
         = g.s by A20
        .= B.((reproj2 [a*x,V20]).s) by FUNCT_2:15
        .= B.([[a*x,V20]`1,s]) by NDIFF_7:def 2
        .= B.(a*x,s) by BINOP_1:def 1
        .= a * B.(x,s) by LOPBAN_8:12
        .= a * B.[[x,V20]`1,s] by BINOP_1:def 1
        .= a * B.((reproj2 [x,V20]).s) by NDIFF_7:def 2
        .= a * f.s by FUNCT_2:15
        .= a * (B1.x).s by A20;
      end;
      hence B1.(a*x) = a * B1.x by LOPBAN_1:36;
    end;
    then reconsider B1 as LinearOperator of
      E,R_NormSpace_of_BoundedLinearOperators(F,G)
      by A24,LOPBAN_1:def 5;

    now
      let V2 be Point of F;
      A25: B2.V2 = B * reproj1([V10,V2]) by A16;
      set L1 = B * reproj1([V10,V2]);
      set z = [V10,V2];

      consider BP0 be Point of R_NormSpace_of_BoundedBilinearOperators(E,F,G)
      such that
      A26: B = BP0
        & ( for x be VECTOR of E
            holds ||.(B * reproj1(z)).x.|| <= ||.BP0.|| * ||.z`2.|| * ||.x.|| )
        & ( for y be VECTOR of F
            holds ||.(B * reproj2(z)).y.|| <= ||.BP0.|| * ||.z`1.|| * ||.y.|| )
            by NDIFF12:2;

      A27: 0 <= ||.BP0.|| by NORMSP_1:4;

      reconsider LL1 = L1 as Lipschitzian LinearOperator
        of E,G by A25,LOPBAN_1:def 9;

      A28:
      now
        let t be VECTOR of E such that
        A29: ||.t.|| <= 1;

        A30: ||.LL1.t.|| <= ||.BP0.|| * ||.z`2.|| * ||.t.|| by A26;
        0 <= ||.z`2.|| by NORMSP_1:4;
        then 0 <= ||.BP0.|| * ||.z`2.|| by A27,XREAL_1:127;
        then ||.BP0.|| * ||.z`2.|| * ||.t.|| <= ||.BP0.|| * ||.z`2.|| * 1
          by A29,XREAL_1:64;
        hence ||.LL1.t.|| <= ||.BP0.|| * ||.z`2.|| by A30,XXREAL_0:2;
      end;

      now
        let r be Real;
        assume r in PreNorms LL1;
        then ex t be VECTOR of E st r = ||.LL1.t.|| & ||.t.|| <= 1;
        hence r <= ||.BP0.|| * ||.z`2.|| by A28;
      end;
      then upper_bound (PreNorms LL1) <= ||.BP0.|| * ||.z`2.|| by SEQ_4:45;

      hence ||.B2.V2.|| <= ||.BP.|| * ||.V2.|| by A25,A26,LOPBAN_1:30;
    end;
    then reconsider B2 as Lipschitzian LinearOperator
      of F,R_NormSpace_of_BoundedLinearOperators(E,G)
      by LOPBAN_1:def 8,NORMSP_1:4;

    now
      let V1 be Point of E;
      A31: B1.V1 = B * reproj2([V1,V20]) by A20;
      set L1= B * reproj2([V1,V20]);
      set z = [V1,V20];
      consider BP0 be Point of R_NormSpace_of_BoundedBilinearOperators(E,F,G)
      such that
      A32: B = BP0
        & (for x be VECTOR of E
           holds ||.(B * reproj1(z)).x.||  <= ||.BP0.|| * ||.z`2.|| * ||.x.||)
        & (for y be VECTOR of F
           holds ||.(B * reproj2(z)). y.|| <= ||.BP0.|| * ||.z`1.|| * ||.y.||)
           by NDIFF12:2;

      A33: 0 <= ||.BP0.|| by NORMSP_1:4;

      reconsider LL1 = L1 as Lipschitzian LinearOperator of F,G
        by A31,LOPBAN_1:def 9;

      A34: (for s be Real st s in PreNorms LL1
            holds s <= ||.BP0.|| * ||.z`1.||)
              implies
            upper_bound PreNorms LL1 <= ||.BP0.|| * ||.z`1.|| by SEQ_4:45;

      A35:
      now
        let t be VECTOR of F such that
        A36: ||.t.|| <= 1;

        A37: ||.LL1.t.|| <= ||.BP0.|| * ||.z`1.|| * ||.t.|| by A32;
        0 <= ||.z`1.|| by NORMSP_1:4;
        then 0 <= ||.BP0.|| * ||.z`1.|| by A33,XREAL_1:127;
        then ||.BP0.|| * ||.z`1.|| * ||.t.|| <= ||.BP0.|| * ||.z`1.|| * 1
        by A36,XREAL_1:64;
        hence ||.LL1.t.|| <= ||.BP0.|| * ||.z`1.|| by A37,XXREAL_0:2;
      end;
      now
        let r be Real;
        assume r in PreNorms LL1;
        then ex t be VECTOR of F st r = ||.LL1.t.|| & ||.t.|| <= 1;
        hence r <= ||.BP0.|| * ||.z`1.|| by A35;
      end;
      hence ||.B1.V1.|| <= ||.BP.|| * ||.V1.|| by A31,A32,A34,LOPBAN_1:30;
    end;
    then reconsider B1 as Lipschitzian LinearOperator of
      E, R_NormSpace_of_BoundedLinearOperators(F,G)
      by LOPBAN_1:def 8,NORMSP_1:4;

    A38: for x be Point of S st x in Z holds
         for V be Point of E holds ((B2*v)/.x).V = B.(V,v/.x)
    proof
      let x be Point of S;
      assume A39: x in Z;
      v/.x in the carrier of F;
      then v/.x in dom B2 by FUNCT_2:def 1;
      then
      A40: (B2*v)/.x
       = B2/.(v/.x) by A6,A39,PARTFUN2:4
      .= B * (reproj1 [V10,v/.x]) by A16;

      let V be Point of E;
      A41: [V10,v/.x]`2 = v/.x;
      thus ((B2*v)/.x).V
       = B.((reproj1 [V10,v/.x]).V) by A40,FUNCT_2:15
      .= B.[V,v/.x] by A41,NDIFF_7:def 1
      .= B.(V,v/.x) by BINOP_1:def 1;
    end;

    A42: for x be Point of S st x in Z
         holds
            for ds be Point of S holds
            B.(((u`|Z)/.x).ds, v/.x) = ((B2*v)/.x * (u`|Z)/.x).ds
    proof
      let x be Point of S;
      assume A43: x in Z;
      let ds be Point of S;

      reconsider F1 = (B2*v)/.x as Lipschitzian LinearOperator of E,G
        by LOPBAN_1:def 9;
      reconsider F2 = (u`|Z)/.x as Lipschitzian LinearOperator of S,E
        by LOPBAN_1:def 9;

      A44: modetrans(F2,S,E) = F2 by LOPBAN_1:def 11;
      A45: dom F2 = the carrier of S by FUNCT_2:def 1;
      thus ((B2*v)/.x * ((u`|Z)/.x)).ds
       = (F1 * F2).ds by A44,LOPBAN_1:def 11
      .= ((B2*v)/.x ).(((u`|Z)/.x).ds) by A45,FUNCT_1:13
      .= B.(((u`|Z)/.x).ds,v/.x) by A38,A43;
    end;

    A46: for x be Point of S st x in Z
         holds
            for V be Point of F
            holds ((B1*u)/.x).V = B.(u/.x,V)
    proof
      let x be Point of S;
      assume A47: x in Z;
      u/.x in the carrier of E;
      then u/.x in dom B1 by FUNCT_2:def 1;
      then
      A48: (B1*u)/.x
       = B1/.(u/.x) by A6,A47,PARTFUN2:4
      .= B * (reproj2 [u/.x,V20]) by A20;

      let V be Point of F;
      A49: [u/.x,V20]`1 = u/.x;
      thus ((B1*u)/.x).V
       = B.((reproj2 [u/.x,V20]).V) by A48,FUNCT_2:15
      .= B.[u/.x,V] by A49,NDIFF_7:def 2
      .= B.(u/.x,V) by BINOP_1:def 1;
    end;

    A50: for x be Point of S st x in Z
         holds
          for ds be Point of S
          holds B.(u/.x,((v`|Z)/.x).ds) = ((B1*u)/.x * (v`|Z)/.x).ds
    proof
      let x be Point of S;
      assume A51: x in Z;
      let ds be Point of S;

      reconsider F1 = (B1*u)/.x as Lipschitzian LinearOperator of F,G
        by LOPBAN_1:def 9;

      reconsider F2 = (v`|Z)/.x as Lipschitzian LinearOperator of S,F
        by LOPBAN_1:def 9;

      A52: modetrans(F2,S,F) = F2 by LOPBAN_1:def 11;
      A53: dom F2 = the carrier of S by FUNCT_2:def 1;

      thus ((B1*u)/.x * (v`|Z)/.x).ds
       = (F1*F2).ds by A52,LOPBAN_1:def 11
      .= ((B1*u)/.x).(((v`|Z)/.x).ds) by A53,FUNCT_1:13
      .= B.(u/.x,((v`|Z)/.x).ds) by A46,A51;
    end;

    A54: for x be Point of S st x in Z
         holds
          for ds be Point of S
          holds ((W`|Z)/.x).ds = ((B2*v)/.x * (u`|Z)/.x).ds
                               + ((B1*u)/.x * (v`|Z)/.x).ds
    proof
      let x be Point of S;
      assume A55: x in Z;
      let ds be Point of S;

      A56: B.(((u`|Z)/.x).ds, v/.x) = ((B2*v)/.x * (u`|Z)/.x).ds by A42,A55;
      thus ((W`|Z)/.x).ds
        = B.(((u`|Z)/.x).ds, v/.x)
        + B.(u/.x, ((v`|Z)/.x).ds) by A6,A8,A9,A55,Th35
       .= ((B2*v)/.x * (u`|Z)/.x).ds
        + ((B1*u)/.x * (v`|Z)/.x).ds by A50,A55,A56;
    end;

    A57: for x be Point of S st x in Z
         holds (W`|Z)/.x = (B2*v)/.x * (u`|Z)/.x + (B1*u)/.x * (v`|Z)/.x
    proof
      let x be Point of S;
      assume x in Z;
      then
      for ds be Point of S
      holds ((W`|Z)/.x).ds = ((B2*v)/.x * (u`|Z)/.x).ds
                           + ((B1*u)/.x * (v`|Z)/.x).ds by A54;

      hence (W`|Z)/.x = (B2*v)/.x * (u`|Z)/.x
                      + (B1*u)/.x * (v`|Z)/.x by LOPBAN_1:35;
    end;

    0 + i <= i + 1 by XREAL_1:7;
    then u is_differentiable_on i,Z
       & v is_differentiable_on i,Z by A6,NDIFF_6:17;
    then
    A58: B1*u is_differentiable_on i,Z
       & B2*v is_differentiable_on i,Z by Th25;

    consider BX1 be Lipschitzian BilinearOperator of
                      R_NormSpace_of_BoundedLinearOperators(S,E),
                      R_NormSpace_of_BoundedLinearOperators(E,G),
                      R_NormSpace_of_BoundedLinearOperators(S,G)
    such that
    A59: for u be Point of R_NormSpace_of_BoundedLinearOperators(S,E),
             v be Point of R_NormSpace_of_BoundedLinearOperators(E,G)
         holds BX1.(u,v) = v * u by Th38;

    set w1 = <:u`|Z, B2*v:>;

    A60: dom w1
     = dom(u`|Z) /\ dom (B2*v) by FUNCT_3:def 7
    .= Z /\ dom(B2*v) by A8,NDIFF_1:def 9
    .= Z by A58,XBOOLE_1:28;
    A61: rng w1 c= [:rng(u`|Z), rng(B2*v):] by FUNCT_3:51;

    [:rng (u`|Z), rng(B2*v):] c= the carrier of
        [:R_NormSpace_of_BoundedLinearOperators(S,E),
          R_NormSpace_of_BoundedLinearOperators(E,G):] by ZFMISC_1:96;

    then rng w1 c= the carrier of
        [:R_NormSpace_of_BoundedLinearOperators(S,E),
          R_NormSpace_of_BoundedLinearOperators(E,G):] by A61,XBOOLE_1:1;

    then reconsider w1 as PartFunc of S,
        [:R_NormSpace_of_BoundedLinearOperators(S,E),
          R_NormSpace_of_BoundedLinearOperators(E,G):] by A60,RELSET_1:4;

    set W1 = BX1 * w1;
    A62: W1 is_differentiable_on i,Z by A5,A11,A58;

    dom BX1 = the carrier of
        [:R_NormSpace_of_BoundedLinearOperators(S,E),
          R_NormSpace_of_BoundedLinearOperators(E,G):] by FUNCT_2:def 1;
    then rng w1 c=dom BX1;
    then A63: dom W1 = Z by A60,RELAT_1:27;

    consider BX2 be Lipschitzian BilinearOperator of
        R_NormSpace_of_BoundedLinearOperators(S,F),
        R_NormSpace_of_BoundedLinearOperators(F,G),
        R_NormSpace_of_BoundedLinearOperators(S,G)
    such that
    A64: for u be Point of R_NormSpace_of_BoundedLinearOperators(S,F),
             v be Point of R_NormSpace_of_BoundedLinearOperators(F,G)
         holds BX2.(u,v) = v * u by Th38;

    set w2 = <:v`|Z, B1*u:>;

    A65: dom w2
     = dom(v`|Z) /\ dom(B1*u) by FUNCT_3:def 7
    .= Z /\ dom(B1*u) by A9,NDIFF_1:def 9
    .= Z by A58,XBOOLE_1:28;

    A66: rng w2 c= [:rng(v`|Z), rng(B1*u):] by FUNCT_3:51;

    [:rng (v`|Z), rng(B1*u):]
    c= [:the carrier of R_NormSpace_of_BoundedLinearOperators(S,F),
         the carrier of R_NormSpace_of_BoundedLinearOperators(F,G):]
        by ZFMISC_1:96;
    then rng w2 c= the carrier of
            [:R_NormSpace_of_BoundedLinearOperators(S,F),
              R_NormSpace_of_BoundedLinearOperators(F,G):]
      by A66,XBOOLE_1:1;
    then reconsider w2 as PartFunc of S,
            [:R_NormSpace_of_BoundedLinearOperators(S,F),
              R_NormSpace_of_BoundedLinearOperators(F,G):]
      by A65,RELSET_1:4;

    set W2 = BX2 * w2;
    A67: W2 is_differentiable_on i,Z by A5,A12,A58;

    dom BX2 = the carrier of
        [:R_NormSpace_of_BoundedLinearOperators(S,F),
          R_NormSpace_of_BoundedLinearOperators(F,G):]
      by FUNCT_2:def 1;
    then rng w2 c= dom BX2;
    then
    A68: dom W2 = Z by A65,RELAT_1:27;
    A69: dom(W`|Z) = Z by A10,NDIFF_1:def 9;
    A70: dom(W1) /\ dom (W2) = Z by A63,A68;

    for c be Element of S st c in dom (W`|Z)
    holds (W`|Z)/.c = W1/.c + W2/.c
    proof
      let x be Element of S;
      assume A71: x in dom (W `| Z);
      A72: dom (u `| Z) = Z by A8,NDIFF_1:def 9;
      A73: W1/.x
       = W1.x by A63,A69,A71,PARTFUN1:def 6
      .= BX1.(w1.x) by A60,A69,A71,FUNCT_1:13
      .= BX1.[(u`|Z).x, (B2*v).x] by A60,A69,A71,FUNCT_3:def 7
      .= BX1.[(u`|Z)/.x, (B2*v).x] by A69,A71,A72,PARTFUN1:def 6
      .= BX1.[(u`|Z)/.x, (B2*v)/.x] by A58,A69,A71,PARTFUN1:def 6
      .= BX1.((u`|Z)/.x, (B2*v)/.x) by BINOP_1:def 1
      .= (B2*v)/.x * (u`|Z)/.x by A59;

      A74: dom (v`|Z) = Z by A9,NDIFF_1:def 9;

      W2/.x
       = W2.x by A68,A69,A71,PARTFUN1:def 6
      .= BX2.(w2.x) by A65,A69,A71,FUNCT_1:13
      .= BX2.[(v`|Z).x, (B1*u).x] by A65,A69,A71,FUNCT_3:def 7
      .= BX2.[(v`|Z)/.x, (B1*u).x] by A69,A71,A74,PARTFUN1:def 6
      .= BX2.[(v`|Z)/.x, (B1*u)/.x] by A58,A69,A71,PARTFUN1:def 6
      .= BX2.((v`|Z)/.x, (B1*u)/.x) by BINOP_1:def 1
      .= (B1*u)/.x * (v`|Z)/.x by A64;
      hence thesis by A57,A69,A71,A73;
    end;

    then A75: W`|Z = W1 + W2 by A69,A70,VFUNCT_1:def 1;

    W `| Z is_differentiable_on i,Z
    proof
      per cases;
      suppose
        i = 0;
        hence W`|Z is_differentiable_on i,Z by A10,NDIFF_1:def 9;
      end;
      suppose
        i <> 0;
        hence W`|Z is_differentiable_on i,Z
          by A62,A67,A75,NDIFF_6:21,NAT_1:14;
      end;
    end;
    hence thesis by A10,Th32;
  end;
  for i be Nat holds P[i] from NAT_1:sch 2(A1,A4);
  hence thesis;
end;
