reserve A,A1,A2,B,C,D for Ordinal,
  X,Y for set,
  x,y,a,b,c for object,
  L,L1,L2,L3 for Sequence,
  f for Function;
reserve fi,psi for Ordinal-Sequence;

theorem Th38:
  A*^0 = 0
proof
  defpred P[Ordinal] means $1*^0 = 0;
A1: for A st P[A] holds P[succ A]
  proof
    let A;
    assume A*^0 = 0;
    hence (succ A)*^0 = 0+^0 by Th36
      .= 0 by Th27;
  end;
A2: for A st A <> 0 & A is limit_ordinal & for B st B in A holds P[B] holds
  P[A]
  proof
    deffunc F(Ordinal) = $1*^0;
    let A;
    assume that
A3: A <> 0 and
A4: A is limit_ordinal and
A5: for B st B in A holds B*^0 = 0;
    consider fi such that
A6: dom fi = A & for B st B in A holds fi.B = F(B) from OSLambda;
    rng fi = succ 0
    proof
      thus for x being object holds  x in rng fi implies x in succ 0
      proof let x be object;
        assume x in rng fi;
        then consider y being object such that
A7:     y in dom fi and
A8:     x = fi.y by FUNCT_1:def 3;
        reconsider y as Ordinal by A7;
        x = y*^0 by A6,A7,A8
          .= 0 by A5,A6,A7;
        hence thesis by TARSKI:def 1;
      end;
      let x be object;
      assume x in succ 0;
      then
A9:   x = 0 by TARSKI:def 1;
      0 c= A;
      then
A10:  0 c< A by A3;
      then
A11:  0 in A by ORDINAL1:11;
      0 *^ 0 = 0 by Th35;
      then fi.x = x by A6,A10,A9,ORDINAL1:11;
      hence thesis by A6,A11,A9,FUNCT_1:def 3;
    end;
    then
A12: sup rng fi = succ 0 by Th18;
    A*^0 = union sup fi by A3,A4,A6,Th37
      .= union sup rng fi;
    hence thesis by A12,Th2;
  end;
A13: P[0] by Th35;
  for A holds P[A] from OrdinalInd(A13,A1,A2);
  hence thesis;
end;
