reserve n for Nat,
        p,p1,p2 for Point of TOP-REAL n,
        x for Real;
reserve n,m for non zero Nat;
reserve i,j for Nat;
reserve f for PartFunc of REAL-NS m,REAL-NS n;
reserve g for PartFunc of REAL m,REAL n;
reserve h for PartFunc of REAL m,REAL;
reserve x for Point of REAL-NS m;
reserve y for Element of REAL m;
reserve X for set;

theorem Th38:
for m,n be non zero Nat, f be PartFunc of REAL m,REAL n,
    X be set holds
f is_continuous_on X iff
X c= dom f &
for x0 be Element of REAL m, r be Real st
 x0 in X & 0<r
 ex s be Real st 0<s & for x1 be Element of REAL m
    st x1 in X & |. x1- x0 .| <s holds |. f/.x1 - f/.x0 .| < r
proof
   let m,n be non zero Nat,
       f be PartFunc of REAL m,REAL n,
       X be set;
    the carrier of REAL-NS m = REAL m &
   the carrier of REAL-NS n = REAL n by REAL_NS1:def 4;
   then reconsider g=f as PartFunc of REAL-NS m,REAL-NS n;
   hereby assume f is_continuous_on X;
then A1: g is_continuous_on X by Th37;
    hence A2: X c= dom f by NFCONT_1:19;
    thus for x0 be Element of REAL m, r be Real st x0 in X & 0<r
    ex s be Real
         st 0 <s & for x1 be Element of REAL m
         st x1 in X & |. x1- x0 .| <s holds |. f/.x1-f/.x0 .|<r
    proof
     let x0 be Element of REAL m, r be Real;
     reconsider y0=x0 as Point of REAL-NS m by REAL_NS1:def 4;
     assume A3: x0 in X & 0<r;
     then consider s be Real such that
A4:   0<s & for y1 be Point of REAL-NS m st y1 in X & ||. y1- y0 .|| < s
       holds ||. g/.y1-g/.y0 .||<r by A1,NFCONT_1:19;
     take s;
     thus 0 < s by A4;
     hereby let x1 be Element of REAL m;
      assume A5: x1 in X & |. x1- x0 .| < s;
      reconsider y1=x1 as Point of REAL-NS m by REAL_NS1:def 4;
       y1 in X & ||. y1- y0 .|| < s by A5,REAL_NS1:1,5;
then A6:   ||. g/.y1-g/.y0 .||<r by A4;
       g/.y1 = f/.x1 & g/.y0 = f/.x0 by A5,A2,A3,Th30;
      hence |. f/.x1-f/.x0 .|<r by A6,REAL_NS1:1,5;
     end;
    end;
   end;
   assume
A7: X c= dom f & for x0 be Element of REAL m,
     r be Real st x0 in X & 0<r ex s be Real
     st 0<s & for x1 be Element of REAL m
     st x1 in X & |. x1- x0 .| <s holds |. f/.x1-f/.x0 .|<r;
    for y0 be Point of REAL-NS m, r be Real st y0 in X & 0<r
     ex s be Real
     st 0 <s & for y1 be Point of REAL-NS m
     st y1 in X & ||. y1- y0 .|| < s
       holds ||. g/.y1-g/.y0 .|| < r
   proof
    let y0 be Point of REAL-NS m,r be Real;
    reconsider x0=y0 as Element of REAL m by REAL_NS1:def 4;
    assume A8: y0 in X & 0<r;
    then consider s be Real such that
A9:  0<s & for x1 be Element of REAL m st x1 in X & |. x1- x0 .| < s
      holds |. f/.x1-f/.x0 .|<r by A7;
    take s;
    thus 0 < s by A9;
    hereby let y1 be Point of REAL-NS m;
     assume A10: y1 in X & ||. y1- y0 .|| < s;
     reconsider x1=y1 as Element of REAL m by REAL_NS1:def 4;
      x1 in X & |. x1- x0 .| < s by A10,REAL_NS1:1,5;
then A11:  |. f/.x1-f/.x0 .|<r by A9;
      g/.y1 = f/.x1 & g/.y0 = f/.x0 by A10,A7,A8,Th30;
     hence ||. g/.y1-g/.y0 .||<r by A11,REAL_NS1:1,5;
    end;
   end;
   then g is_continuous_on X by A7,NFCONT_1:19;
   hence f is_continuous_on X by Th37;
end;
