reserve L for Ortholattice,
  a, b, c for Element of L;

theorem
  for L being non empty OrthoLattStr holds L is Orthomodular_Lattice iff
(for a, b, c being Element of L holds (a "\/" b) "\/" c = (c` "/\" b`)` "\/" a)
& (for a, b,c being Element of L holds a "\/" b = ((a "\/" b) "/\" (a "\/" c))
  "\/" ((a "\/" b) "/\" a`)) & for a, b being Element of L holds a = a "\/" (b
  "/\" b`)
proof
  let L be non empty OrthoLattStr;
  thus L is Orthomodular_Lattice implies (for a, b, c being Element of L holds
  (a "\/" b) "\/" c = (c` "/\" b`)` "\/" a) & (for a, b,c being Element of L
holds a "\/" b = ((a "\/" b) "/\" (a "\/" c)) "\/" ((a "\/" b) "/\" a`)) & for
  a, b being Element of L holds a = a "\/" (b "/\" b`)
  proof
    assume
A1: L is Orthomodular_Lattice;
    hence
    for a, b, c being Element of L holds (a "\/" b) "\/" c = (c` "/\" b`)
    ` "\/" a by Th3;
    thus for a, b,c being Element of L holds a "\/" b = ((a "\/" b) "/\" (a
    "\/" c)) "\/" ((a "\/" b) "/\" a`)
    proof
      let a,b,c be Element of L;
      (a"\/"b)"/\"a` [= a "\/"b & (a"\/"b)"/\"(a"\/"c) [= a "\/"b by A1,
LATTICES:6;
      then
A2:   ((a"\/"b)"/\"(a"\/"c))"\/"((a"\/"b)"/\"a`) [= a "\/"b by A1,FILTER_0:6;
      a"/\"(a"\/"b)[=(a"\/"c)"/\"(a"\/"b) by A1,LATTICES:5,9;
      then (a"\/"b)"/\"a[=(a"\/"c)"/\"(a"\/"b) by A1,LATTICES:def 6;
      then (a"\/"b)"/\"a[= (a"\/"b)"/\"(a"\/"c) by A1,LATTICES:def 6;
      then
      ((a"\/"b)"/\"a`)"\/"((a"\/"b)"/\"a)[= ((a"\/"b)"/\"a`)"\/"((a"\/"b)
      "/\"(a"\/"c)) by A1,FILTER_0:1;
      then
A3:   ((a"\/"b)"/\"a)"\/"((a"\/"b)"/\"a`)[= ((a"\/"b)"/\"a`)"\/"((a"\/"b)
      "/\"(a"\/"c))by A1,LATTICES:def 4;
      a"\/"b=((a"\/"b)"/\"a)"\/"((a"\/"b)"/\"a`) by A1,Th36;
      then a "\/"b [= ((a"\/"b)"/\"(a"\/"c))"\/"((a"\/"b)"/\"a`) by A1,A3,
LATTICES:def 4;
      hence thesis by A1,A2,LATTICES:8;
    end;
    thus thesis by A1,Th3;
  end;
  assume
A4: for a, b, c being Element of L holds (a "\/" b) "\/" c = (c` "/\" b
  `)` "\/" a;
  assume
A5: for a, b,c being Element of L holds a "\/" b = ((a"\/"b)"/\"(a"\/"c
  ))"\/"((a"\/"b)"/\"a`);
  assume
A6: for a, b being Element of L holds a = a "\/" (b "/\" b`);
A7: for a,b being Element of L holds a "\/" b = ((a "\/" b) "/\" a) "\/" ((
  a "\/" b) "/\" a`)
  proof
    let a,b be Element of L;
    set c = a "/\" a`;
    a "\/" b = ((a "\/" b) "/\" (a "\/" c)) "\/" ((a "\/" b) "/\" a`) by A5;
    hence thesis by A6;
  end;
  for a, c being Element of L holds a = a "/\" (a"\/"c)
  proof
    let a,c be Element of L;
    set b = a "/\" a`;
    thus a = a "\/" b by A6
      .= ((a"\/"b)"/\"(a"\/"c))"\/"((a"\/"b)"/\"a`) by A5
      .= (a"/\"(a"\/"c))"\/"((a"\/"b)"/\"a`) by A6
      .= (a"/\"(a"\/"c))"\/"(a"/\"a`) by A6
      .= a"/\"(a"\/"c) by A6;
  end;
  then L is Ortholattice by A4,A6,Th3;
  hence thesis by A7,Th36;
end;
