reserve x,y,X for set,
        r for Real,
        n,k for Nat;
reserve RLS for non empty RLSStruct,
        Kr,K1r,K2r for SimplicialComplexStr of RLS,
        V for RealLinearSpace,
        Kv for non void SimplicialComplex of V;
reserve Ks for simplex-join-closed SimplicialComplex of V,
        As,Bs for Subset of Ks,
        Ka for non void affinely-independent SimplicialComplex of V,
        Kas for non void affinely-independent simplex-join-closed
                 SimplicialComplex of V,
        K for non void affinely-independent simplex-join-closed total
                 SimplicialComplex of V;
reserve Aff for finite affinely-independent Subset of V,
        Af,Bf for finite Subset of V,
        B for Subset of V,
        S,T for finite Subset-Family of V,
        Sf for c=-linear finite finite-membered Subset-Family of V,
        Sk,Tk for finite simplex-like Subset-Family of K,
        Ak for Simplex of K;

theorem Th38:
  for Sf st Sf is with_non-empty_elements & card Sf = card union Sf
  for v be Element of V st not v in union Sf &
                           union Sf\/{v} is affinely-independent
  holds
   {S1 where S1 is Simplex of card Sf,BCS Complex_of{union Sf\/{v}}:
       (center_of_mass V).:Sf c= S1} =
   {(center_of_mass V).:Sf\/(center_of_mass V).:{union Sf\/{v}}}
 proof
  let S be finite c=-linear finite-membered Subset-Family of V such that
   A1: S is with_non-empty_elements and
   A2: card S=card union S;
  set U=union S;
  set B=center_of_mass V;
  let v be Element of V such that
   A3: not v in U and
   A4: U\/{v} is affinely-independent;
  reconsider Uv=U\/{v} as finite affinely-independent Subset of V by A4;
  set CUv=Complex_of{Uv};
  set BC=BCS CUv;
  set SS={S1 where S1 is Simplex of card S,BCS Complex_of{union S\/{v}}:B.:S
c=S1};
  set TT={B.:S\/B.:{union S\/{v}}};
  A5: U c=Uv by XBOOLE_1:7;
  hereby let x be object;
   reconsider n=0 as Nat;
   assume x in SS;
   then consider S1 be Simplex of card S,BC such that
    A6: x=S1 and
    A7: B.:S c=S1;
   card S+n+1<=card Uv by A2,A3,CARD_2:41;
   then consider T be finite Subset-Family of V such that
    A8: T misses S and
    A9: T\/S is c=-linear with_non-empty_elements and
    A10: card T=n+1 and
    A11: union T c=Uv and
    A12: @S1=(center_of_mass V).:S\/(center_of_mass V).:T by A1,A5,A7,Th35;
   A13: ex x being object st T={x} by A10,CARD_2:42;
   A14: union(T\/S)=union T\/union S by ZFMISC_1:78;
   T\/S is finite-membered
   proof
    let x;
    assume x in T\/S;
    then x c=union(T\/S) by ZFMISC_1:74;
    hence thesis by A11,A14;
   end;
   then reconsider TS=T\/S as finite finite-membered Subset-Family of V;
   union(T\/S)c=Uv by A5,A11,A14,XBOOLE_1:8;
   then A15: card union TS c=card Uv by CARD_1:11;
   card TS=card S+1 by A8,A10,CARD_2:40;
   then A16: card TS=card Uv by A2,A3,CARD_2:41;
   card TS c=card union TS by A9,SIMPLEX0:10;
   then card union TS=card TS by A15,A16;
   then A17: union TS=Uv by A5,A11,A14,A16,CARD_2:102,XBOOLE_1:8;
   A18: union S c=union(T\/S) by A14,XBOOLE_1:7;
   A19: not union TS in S
   proof
    assume union TS in S;
    then union TS c=U by ZFMISC_1:74;
    then A20: U=Uv by A17,A18;
    v in {v} by TARSKI:def 1;
    hence thesis by A3,A20,XBOOLE_0:def 3;
   end;
   T is non empty by A10;
   then union TS in TS by A9,SIMPLEX0:9;
   then union TS in T by A19,XBOOLE_0:def 3;
   then T={Uv} by A13,A17,TARSKI:def 1;
   hence x in TT by A6,A12,TARSKI:def 1;
  end;
  let x be object;
  assume x in TT;
  then A21: x=B.:S\/B.:{Uv} by TARSKI:def 1;
  B.:S c=B.:S\/B.:{Uv} & B.:S\/B.:{Uv} is Simplex of card S,BC by A1,A2,A3,Th37
,XBOOLE_1:7,ZFMISC_1:50;
  hence thesis by A21;
 end;
