reserve T,T1,T2 for TopSpace,
  A,B for Subset of T,
  F for Subset of T|A,
  G,G1, G2 for Subset-Family of T,
  U,W for open Subset of T|A,
  p for Point of T|A,
  n for Nat,
  I for Integer;
reserve Af for finite-ind Subset of T,
  Tf for finite-ind TopSpace;
reserve TM for metrizable TopSpace;

theorem Th38:
  for Null be Subset of TM st TM|Null is second-countable holds
  Null is finite-ind & ind Null<=0 iff for p be Point of TM,U be open Subset of
  TM st p in U ex W be open Subset of TM st p in W & W c=U & Null misses Fr W
proof
  let Null be Subset of TM such that
A1: TM|Null is second-countable;
  hereby
    assume
A2: Null is finite-ind & ind Null<=0;
    let p be Point of TM,U be open Subset of TM such that
A3: p in U;
    reconsider P={p} as Subset of TM by A3,ZFMISC_1:31;
    not p in U` by A3,XBOOLE_0:def 5;
    then
A4: P misses U` by ZFMISC_1:50;
    TM is non empty by A3;
    then consider L be Subset of TM such that
A5: L separates P,U` and
A6: L misses Null by A1,A2,A4,Th37;
    consider W,W1 be open Subset of TM such that
A7: P c=W and
A8: U`c=W1 and
A9: W misses W1 and
A10: L=(W\/W1)` by A5,METRIZTS:def 3;
    take W;
    W c=W1` & W1`c=U`` by A8,A9,SUBSET_1:12,23;
    hence p in W & W c=U by A7,ZFMISC_1:31;
    thus Null misses Fr W
    proof
      assume Null meets Fr W;
      then consider x be object such that
A11:  x in Fr W and
A12:  x in Null by XBOOLE_0:3;
      Null c=L` by A6,SUBSET_1:23;
      then
A13:  x in W or x in W1 by A10,A12,XBOOLE_0:def 3;
A14:  x in (Cl W)\W by A11,TOPS_1:42;
      then x in Cl W by XBOOLE_0:def 5;
      then Cl W meets W1 by A13,A14,XBOOLE_0:3,def 5;
      hence contradiction by A9,TSEP_1:36;
    end;
  end;
  set TN=TM|Null;
  assume
A15: for p be Point of TM,U be open Subset of TM st p in U ex W be open
  Subset of TM st p in W & W c=U & Null misses Fr W;
A16: for p be Point of TN,U be open Subset of TN st p in U ex W be open
  Subset of TN st p in W & W c=U & Fr W is finite-ind & ind Fr W<=0-1
  proof
    let p be Point of TN,U be open Subset of TN such that
A17: p in U;
A18: [#]TN=Null by PRE_TOPC:def 5;
    then p in Null by A17;
    then reconsider p9=p as Point of TM;
    consider U9 be Subset of TM such that
A19: U9 is open and
A20: U=U9/\the carrier of TN by TSP_1:def 1;
    p9 in U9 by A17,A20,XBOOLE_0:def 4;
    then consider W9 be open Subset of TM such that
A21: p9 in W9 & W9 c=U9 and
A22: Null misses Fr W9 by A15,A19;
    reconsider W=W9/\the carrier of TN as Subset of TN by XBOOLE_1:17;
    reconsider W as open Subset of TN by TSP_1:def 1;
    take W;
    thus p in W & W c=U by A17,A20,A21,XBOOLE_0:def 4,XBOOLE_1:26;
A23: Fr W9/\Null={} by A22;
    Fr W c=Fr W9/\Null by A18,Th1;
    hence thesis by A23,Th6;
  end;
  then
A24: TN is finite-ind by Th15;
  then
A25: Null is finite-ind by Th18;
  ind TN<=0 by A16,A24,Th16;
  hence thesis by A25,Lm5;
end;
