reserve N for Nat;
reserve n,m,n1,n2 for Nat;
reserve q,r,r1,r2 for Real;
reserve x,y for set;
reserve w,w1,w2,g,g1,g2 for Point of TOP-REAL N;
reserve seq,seq1,seq2,seq3,seq9 for Real_Sequence of N;

theorem Th38:
  seq is convergent implies r*seq is convergent
proof
  assume seq is convergent;
  then consider g1 such that
A1: for q st 0<q ex n st for m st n<=m holds |.seq.m-g1.|<q;
  set g=r*g1;
A2: now
A3: 0/|.r.|=0;
    assume
A4: r<>0;
    then
A5: 0<|.r.| by COMPLEX1:47;
    let q;
    assume 0<q;
    then consider n1 such that
A6: for m st n1<=m holds |.seq.m-g1.|<q/|.r.| by A1,A5,A3,XREAL_1:74;
    take k=n1;
    let m;
    assume k<=m;
    then
A7: |.seq.m-g1.|<q/|.r.| by A6;
A8: 0<|.r.| by A4,COMPLEX1:47;
A9: |.r.|*(q/|.r.|)=|.r.|*(|.r.|"*q) by XCMPLX_0:def 9
      .=|.r.|*|.r.|"*q
      .=1*q by A8,XCMPLX_0:def 7
      .=q;
    |.((r*seq).m)-g.|=|.r*seq.m-r*g1.| by Th5
      .=|.r*(seq.m-g1).| by RLVECT_1:34
      .=|.r.|*|.seq.m-g1.| by Th7;
    hence |.((r*seq).m)-g.|<q by A5,A7,A9,XREAL_1:68;
  end;
  now
    assume
A10: r=0;
    let q such that
A11: 0<q;
     reconsider k=0 as Nat;
    take k;
    let m such that
    k<=m;
    |.((r*seq).m)-g.|=|.((0 *seq).m)-0.TOP-REAL N.| by A10,RLVECT_1:10
      .=|.0.TOP-REAL N-((0 * seq).m).| by Th27
      .=|.0.TOP-REAL N+-((0 * seq).m).|
      .=|.-((0 * seq).m).| by RLVECT_1:4
      .=|.(0 * seq).m.| by EUCLID:71
      .=|.0 * seq.m.| by Th5
      .=|.0.TOP-REAL N.| by RLVECT_1:10
      .=0 by Th23;
    hence |.((r*seq).m)-g.|<q by A11;
  end;
  hence thesis by A2;
end;
