reserve R for non empty RelStr,
  N for net of R,
  i for Element of N;

theorem :: Corrollary to Proposition 1.6 (p.103)
  for T be continuous complete Scott TopLattice, x be Element of T,
  N be net of T st N in NetUniv T holds x is_S-limit_of N iff x in Lim N
proof
  let T be continuous complete Scott TopLattice, x be Element of T,
  N be net of T such that
A1: N in NetUniv T;
A2: Convergence ConvergenceSpace Scott-Convergence T
  = Scott-Convergence T by YELLOW_6:44;
  consider M being strict net of T such that
A3: M = N and
  the carrier of M in the_universe_of the carrier of T by A1,YELLOW_6:def 11;
  the TopStruct of T = ConvergenceSpace Scott-Convergence T by Th32;
  then
A4: Convergence T = Convergence ConvergenceSpace Scott-Convergence T by Lm8;
  thus x is_S-limit_of N implies x in Lim N
  proof
    assume x is_S-limit_of N;
    then [N,x] in Convergence T by A1,A2,A3,A4,Def8;
    hence thesis by YELLOW_6:def 19;
  end;
  assume x in Lim N;
  then [M,x] in Scott-Convergence T by A1,A2,A3,A4,YELLOW_6:def 19;
  hence thesis by A1,A3,Def8;
end;
