reserve X1, X2, Y for non empty RelStr,
  f for Function of [:X1, X2:], Y,
  x for Element of X1,
  y for Element of X2;
reserve S for non empty RelStr,
  T for complete LATTICE;

theorem
  for S, T being Scott complete TopLattice holds SCMaps (S, T) =
  ContMaps (S, T)
proof
  let S, T be Scott complete TopLattice;
  reconsider Sm = ContMaps (S, T) as full non empty SubRelStr of (T |^ the
  carrier of S) by Def3;
  reconsider SC = SCMaps (S, T) as full non empty SubRelStr of (T |^ the
  carrier of S) by WAYBEL15:1;
A1: the carrier of SC c= the carrier of MonMaps (S, T) by YELLOW_0:def 13;
A2: the carrier of SC c= the carrier of Sm
  proof
    let a be object;
    assume
A3: a in the carrier of SC;
    then reconsider f = a as Function of S, T by A1,WAYBEL10:9;
    f is continuous Function of S, T by A3,WAYBEL17:def 2;
    then a is Element of Sm by Th21;
    hence thesis;
  end;
  the carrier of Sm c= the carrier of SC
  proof
    let a be object;
    assume a in the carrier of Sm;
    then a is continuous Function of S, T by Th21;
    hence thesis by WAYBEL17:def 2;
  end;
  then the carrier of SC = the carrier of Sm by A2;
  hence thesis by YELLOW_0:57;
end;
