reserve i,j for Nat;
reserve i,j for Nat,
  x for variable,
  l for quasi-loci;
reserve C for initialized ConstructorSignature,
  c for constructor OperSymbol of C;
reserve a,a9 for quasi-adjective,
  t,t1,t2 for quasi-term,
  T for quasi-type,

  c for Element of Constructors;

theorem Th39:
 for o being nullary OperSymbol of C holds
   [o, the carrier of C]-tree {} is expression of C, the_result_sort_of o
  proof
   let o be nullary OperSymbol of C;
   set X = MSVars C;
   set Z = (the carrier of C)-->{0};
   set Y = X (\/) Z;
A1: the_arity_of o = {} by Def13;
A2: the Sorts of Free(C, X) = C-Terms(X, Y) by MSAFREE3:24;
    for i being Nat st i in dom {} ex t being Term of C,Y st t = {}.i &
    the_sort_of t = (the_arity_of o).i; then
   reconsider p = {} as ArgumentSeq of Sym(o, Y) by A1,MSATERM:24;
A3: variables_in (Sym(o, Y)-tree p) c= X
     proof let s be object; assume s in the carrier of C; then
      reconsider s9 = s as SortSymbol of C;
      let x be object; assume x in (variables_in (Sym(o, Y)-tree p)).s; then
       ex t being DecoratedTree st t in rng p & x in (C variables_in t).s9
       by MSAFREE3:11;
      hence thesis;
     end;
   set s9 = the_result_sort_of o;
A4: the_sort_of (Sym(o, Y)-tree p) = the_result_sort_of o by MSATERM:20;
    (the Sorts of Free(C, X)).s9 =
     {t where t is Term of C,Y: the_sort_of t = s9 & variables_in t c= X}
      by A2,MSAFREE3:def 5; then
    [o, the carrier of C]-tree {} in (the Sorts of Free(C, X)).s9 by A3,A4;
   hence thesis by ABCMIZ_1:41;
  end;
