reserve x, x1, x2, y, X, D for set,
  i, j, k, l, m, n, N for Nat,
  p, q for XFinSequence of NAT,
  q9 for XFinSequence,
  pd, qd for XFinSequence of D;
reserve pN, qN for Element of NAT^omega;

theorem Th39:
  for n st n > 0 ex Catal be XFinSequence of NAT st Sum Catal =
  Catalan(n+1) & dom Catal = n & for j st j < n holds Catal.j = Catalan(j+1)*
  Catalan(n-'j)
proof
  let n such that
A1: n>0;
  consider CardF be XFinSequence of NAT such that
A2: card {pN: pN in Domin_0(2*n,n) & {N:2*Sum(pN|N)=N&N>0}<>{}}=Sum CardF and
A3: dom CardF = n and
A4: for j st j < n holds CardF.j=card Domin_0(2*j,j)*card Domin_0(2*n-'2
  *(j+1),n-'(j+1)) by Th37;
  take CardF;
  Sum CardF= card Domin_0(2*n,n) by A1,A2,Th38;
  hence Sum CardF=Catalan(n+1) & dom CardF =n by A3,Th34;
  let j such that
A5: j < n;
  n-j > j-j by A5,XREAL_1:9;
  then n-'j >0 by A5,XREAL_1:233;
  then reconsider nj=(n-'j)-1 as Nat by NAT_1:20;
  j+1<=n by A5,NAT_1:13;
  then
A6: 2*n-'2*(j+1)=2*n-2*(j+1) & n-'(j+1)=n-(j+1) by XREAL_1:64,233;
A7: card Domin_0(2*j,j)=Catalan(j+1) by Th34;
  n-j=n-'j by A5,XREAL_1:233;
  then card Domin_0(2*n-'2*(j+1),n-'(j+1))=card Domin_0(2*nj,nj) by A6
    .=Catalan(nj+1) by Th34;
  hence thesis by A4,A5,A7;
end;
