
theorem
  for C1, C2 being Coherence_Space for f being U-stable Function of C1,
  C2 for a being Element of C1 holds f.a = (Trace f).:Fin a
proof
  let C1, C2 be Coherence_Space;
  let f be U-stable Function of C1,C2;
  let a be Element of C1;
  set X = Trace f;
A1: dom f = C1 by FUNCT_2:def 1;
A2: now
    let x be set;
    assume
A3: x in X;
    then consider a, y being set such that
A4: x = [a,y] and
    a in dom f and
    y in f.a and
    for b being set st b in dom f & b c= a & y in f.b holds a = b by Def17;
    a is finite by A1,A3,A4,Th33;
    hence x`1 is finite by A4;
  end;
  ( for a,b being Element of C1 st a \/ b in C1
for y1,y2 being object st [a,
  y1] in X & [b,y2] in X holds {y1,y2} in C2)& for a,b being Element of C1 st a
\/ b in C1
for y being object st [a,y] in X & [b,y] in X holds a = b by Th34,Th35;
  then consider g being U-stable Function of C1,C2 such that
A5: X = Trace g and
A6: for a being Element of C1 holds g.a = X.:Fin a by A2,Lm5;
  g.a = X.:Fin a by A6;
  hence thesis by A5,Th37;
end;
