reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th39:
  for sn being Real st -1<sn & sn<1 holds sn-FanMorphW is Function
  of TOP-REAL 2,TOP-REAL 2 & rng (sn-FanMorphW) = the carrier of TOP-REAL 2
proof
  let sn be Real;
  assume that
A1: -1<sn and
A2: sn<1;
  thus sn-FanMorphW is Function of TOP-REAL 2,TOP-REAL 2;
  for f being Function of TOP-REAL 2,TOP-REAL 2 st f=(sn-FanMorphW) holds
  rng (sn-FanMorphW)=the carrier of TOP-REAL 2
  proof
    let f be Function of TOP-REAL 2,TOP-REAL 2;
    assume
A3: f=sn-FanMorphW;
A4: dom f=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
    the carrier of TOP-REAL 2 c= rng f
    proof
      let y be object;
      assume y in the carrier of TOP-REAL 2;
      then reconsider p2=y as Point of TOP-REAL 2;
      set q=p2;
      now
        per cases by JGRAPH_2:3;
        case
          q`1>=0;
          then y=(sn-FanMorphW).q by Th16;
          hence ex x being set st x in dom (sn-FanMorphW) & y=(sn-FanMorphW).x
          by A3,A4;
        end;
        case
A5:       q`2/|.q.|>=0 & q`1<=0 & q<>0.TOP-REAL 2;
A6:       --(1+sn)>0 by A1,XREAL_1:148;
A7:       1-sn>=0 by A2,XREAL_1:149;
          then q`2/|.q.|*(1-sn)>=0 by A5;
          then -(1+sn)<= q`2/|.q.|*(1-sn) by A6;
          then
A8:       -1-sn+sn<= q`2/|.q.|*(1-sn)+sn by XREAL_1:7;
          set px=|[ -(|.q.|)*sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2), |.q.|*(q`2/|.q.|
          *(1-sn)+sn)]|;
A9:       px`2 = |.q.|*(q`2/|.q.|*(1-sn)+sn) by EUCLID:52;
          |.q.|<>0 by A5,TOPRNS_1:24;
          then
A10:      |.q.|^2>0 by SQUARE_1:12;
A11:      |.q.|>0 by A5,Lm1;
A12:      dom (sn-FanMorphW)=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
A13:      1-sn>0 by A2,XREAL_1:149;
          0<=(q`1)^2 by XREAL_1:63;
          then (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`2)^2<=(q`1)^2+(q`2)^2 by
JGRAPH_3:1,XREAL_1:7;
          then (q`2)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
          then (q`2)^2/(|.q.|)^2 <= 1 by A10,XCMPLX_1:60;
          then ((q`2)/|.q.|)^2 <= 1 by XCMPLX_1:76;
          then q`2/|.q.|<=1 by SQUARE_1:51;
          then q`2/|.q.|*(1-sn) <=1 *(1-sn) by A13,XREAL_1:64;
          then q`2/|.q.|*(1-sn)+sn-sn <=1-sn;
          then (q`2/|.q.|*(1-sn)+sn) <=1 by XREAL_1:9;
          then 1^2>=(q`2/|.q.|*(1-sn)+sn)^2 by A8,SQUARE_1:49;
          then
A14:      1-(q`2/|.q.|*(1-sn)+sn)^2>=0 by XREAL_1:48;
          then
A15:      sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2)>=0 by SQUARE_1:def 2;
A16:      px`1 = -(|.q.|)*sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2) by EUCLID:52;
          then
          |.px.|^2=(-(|.q.|)*sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2))^2 +(|.q.|*(
          q`2/|.q.|*(1-sn)+sn))^2 by A9,JGRAPH_3:1
            .=(|.q.|)^2*(sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2))^2 +(|.q.|)^2*((q`2
          /|.q.|*(1-sn)+sn))^2;
          then
A17:      |.px.|^2=(|.q.|)^2*(1-(q`2/|.q.|*(1-sn)+sn)^2) +(|.q.|)^2*((q`2
          /|.q.|*(1-sn)+sn))^2 by A14,SQUARE_1:def 2
            .= (|.q.|)^2;
          then
A18:      |.px.|=sqrt(|.q.|^2) by SQUARE_1:22
            .=|.q.| by SQUARE_1:22;
          then
A19:      px<>0.TOP-REAL 2 by A5,TOPRNS_1:23,24;
          (q`2/|.q.|*(1-sn)+sn)>=0+sn by A5,A7,XREAL_1:7;
          then px`2/|.px.| >=sn by A5,A9,A18,TOPRNS_1:24,XCMPLX_1:89;
          then
A20:      (sn-FanMorphW).px =|[ |.px.|*(-sqrt(1-((px`2/|.px.|-sn )/(1-sn)
          )^2)), |.px.|* ((px`2/|.px.|-sn)/(1-sn))]| by A1,A2,A16,A15,A19,Th18;
A21:      |.px.|*(-sqrt((q`1/|.q.|)^2))=|.px.|*(--(q`1/|.q.|)) by A5,
SQUARE_1:23
            .=q`1 by A11,A18,XCMPLX_1:87;
A22:      |.px.|* ((px`2/|.px.|-sn)/(1-sn)) =|.q.|* (( ((q`2/|.q.|*(1-sn)
          +sn))-sn)/(1-sn)) by A5,A9,A18,TOPRNS_1:24,XCMPLX_1:89
            .=|.q.|* ( q`2/|.q.|) by A13,XCMPLX_1:89
            .= q`2 by A5,TOPRNS_1:24,XCMPLX_1:87;
          then
          |.px.|*(-sqrt(1-((px`2/|.px.|-sn)/(1-sn))^2)) = |.px.|*(-sqrt(1
          -(q`2/|.px.|)^2)) by A5,A18,TOPRNS_1:24,XCMPLX_1:89
            .= |.px.|*(-sqrt(1-(q`2)^2/(|.px.|)^2)) by XCMPLX_1:76
            .= |.px.|*(-sqrt( (|.px.|)^2/(|.px.|)^2-(q`2)^2/(|.px.|)^2)) by A10
,A17,XCMPLX_1:60
            .= |.px.|*(-sqrt( ((|.px.|)^2-(q`2)^2)/(|.px.|)^2)) by XCMPLX_1:120
            .= |.px.|*(-sqrt( ((q`1)^2+(q`2)^2-(q`2)^2)/(|.px.|)^2)) by A17,
JGRAPH_3:1
            .= |.px.|*(-sqrt((q`1/|.q.|)^2)) by A18,XCMPLX_1:76;
          hence ex x being set st x in dom (sn-FanMorphW) & y=(sn-FanMorphW).x
          by A20,A22,A21,A12,EUCLID:53;
        end;
        case
A23:      q`2/|.q.|<0 & q`1<=0 & q<>0.TOP-REAL 2;
A24:      1+sn>=0 by A1,XREAL_1:148;
          then q`2/|.q.|*(1+sn)<=0 by A23;
          then 1-sn>= q`2/|.q.|*(1+sn) by A2,XREAL_1:149;
          then
A25:      1-sn+sn>= q`2/|.q.|*(1+sn)+sn by XREAL_1:7;
          set px=|[ -(|.q.|)*sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2), |.q.|*(q`2/|.q.|
          *(1+sn)+sn)]|;
A26:      px`2 = |.q.|*(q`2/|.q.|*(1+sn)+sn) by EUCLID:52;
          |.q.|<>0 by A23,TOPRNS_1:24;
          then
A27:      |.q.|^2>0 by SQUARE_1:12;
A28:      |.q.|>0 by A23,Lm1;
A29:      dom (sn-FanMorphW)=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
A30:      1+sn>0 by A1,XREAL_1:148;
          0<=(q`1)^2 by XREAL_1:63;
          then (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`2)^2<=(q`1)^2+(q`2)^2 by
JGRAPH_3:1,XREAL_1:7;
          then (q`2)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
          then (q`2)^2/(|.q.|)^2 <= 1 by A27,XCMPLX_1:60;
          then ((q`2)/|.q.|)^2 <= 1 by XCMPLX_1:76;
          then q`2/|.q.|>=-1 by SQUARE_1:51;
          then q`2/|.q.|*(1+sn) >=(-1)*(1+sn) by A30,XREAL_1:64;
          then q`2/|.q.|*(1+sn)+sn-sn >=-1-sn;
          then (q`2/|.q.|*(1+sn)+sn) >=-1 by XREAL_1:9;
          then 1^2>=(q`2/|.q.|*(1+sn)+sn)^2 by A25,SQUARE_1:49;
          then
A31:      1-(q`2/|.q.|*(1+sn)+sn)^2>=0 by XREAL_1:48;
          then
A32:      sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2)>=0 by SQUARE_1:def 2;
A33:      px`1 = -(|.q.|)*sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2) by EUCLID:52;
          then
          |.px.|^2=(-(|.q.|)*sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2))^2 +(|.q.|*(
          q`2/|.q.|*(1+sn)+sn))^2 by A26,JGRAPH_3:1
            .=(|.q.|)^2*(sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2))^2 +(|.q.|)^2*((q`2
          /|.q.|*(1+sn)+sn))^2;
          then
A34:      |.px.|^2=(|.q.|)^2*(1-(q`2/|.q.|*(1+sn)+sn)^2) +(|.q.|)^2*((q`2
          /|.q.|*(1+sn)+sn))^2 by A31,SQUARE_1:def 2
            .= (|.q.|)^2;
          then
A35:      |.px.|=sqrt(|.q.|^2) by SQUARE_1:22
            .=|.q.| by SQUARE_1:22;
          then
A36:      px<>0.TOP-REAL 2 by A23,TOPRNS_1:23,24;
          (q`2/|.q.|*(1+sn)+sn)<=0+sn by A23,A24,XREAL_1:7;
          then px`2/|.px.| <=sn by A23,A26,A35,TOPRNS_1:24,XCMPLX_1:89;
          then
A37:      (sn-FanMorphW).px =|[ |.px.|*(-sqrt(1-((px`2/|.px.|-sn )/(1+sn)
          )^2)), |.px.|* ((px`2/|.px.|-sn)/(1+sn))]| by A1,A2,A33,A32,A36,Th18;
A38:      |.px.|*(-sqrt((q`1/|.q.|)^2))=|.px.|*(--(q`1/|.q.|)) by A23,
SQUARE_1:23
            .=q`1 by A28,A35,XCMPLX_1:87;
A39:      |.px.|* ((px`2/|.px.|-sn)/(1+sn)) =|.q.|* (( ((q`2/|.q.|*(1+sn)
          +sn))-sn)/(1+sn)) by A23,A26,A35,TOPRNS_1:24,XCMPLX_1:89
            .=|.q.|* ( q`2/|.q.|) by A30,XCMPLX_1:89
            .= q`2 by A23,TOPRNS_1:24,XCMPLX_1:87;
          then
          |.px.|*(-sqrt(1-((px`2/|.px.|-sn)/(1+sn))^2)) = |.px.|*(-sqrt(1
          -(q`2/|.px.|)^2)) by A23,A35,TOPRNS_1:24,XCMPLX_1:89
            .= |.px.|*(-sqrt(1-(q`2)^2/(|.px.|)^2)) by XCMPLX_1:76
            .= |.px.|*(-sqrt( (|.px.|)^2/(|.px.|)^2-(q`2)^2/(|.px.|)^2)) by A27
,A34,XCMPLX_1:60
            .= |.px.|*(-sqrt( ((|.px.|)^2-(q`2)^2)/(|.px.|)^2)) by XCMPLX_1:120
            .= |.px.|*(-sqrt( ((q`1)^2+(q`2)^2-(q`2)^2)/(|.px.|)^2)) by A34,
JGRAPH_3:1
            .= |.px.|*(-sqrt((q`1/|.q.|)^2)) by A35,XCMPLX_1:76;
          hence ex x being set st x in dom (sn-FanMorphW) & y=(sn-FanMorphW).x
          by A37,A39,A38,A29,EUCLID:53;
        end;
      end;
      hence thesis by A3,FUNCT_1:def 3;
    end;
    hence thesis by A3,XBOOLE_0:def 10;
  end;
  hence thesis;
end;
