
theorem
  for X,Y,Z,W be RealNormSpace,
      I be Lipschitzian LinearOperator of X,Z,
      J be Lipschitzian LinearOperator of Y,W
   st I is one-to-one onto isometric
    & J is one-to-one onto isometric
  holds
    ex K be Lipschitzian LinearOperator of
      R_NormSpace_of_BoundedLinearOperators(X,Y),
      R_NormSpace_of_BoundedLinearOperators(Z,W)
    st K is one-to-one onto isometric
     & for x be Point of R_NormSpace_of_BoundedLinearOperators(X,Y)
       holds K.x = J * (x * I")
  proof
    let X,Y,Z,W be RealNormSpace,
      I be Lipschitzian LinearOperator of X,Z,
      J be Lipschitzian LinearOperator of Y,W;

    assume
    A1: I is one-to-one onto isometric
      & J is one-to-one onto isometric;

    consider H be Lipschitzian LinearOperator of
      R_NormSpace_of_BoundedLinearOperators(X,Y),
      R_NormSpace_of_BoundedLinearOperators(Z,Y)
    such that
    A2: H is one-to-one onto isometric
      & for x be Point of R_NormSpace_of_BoundedLinearOperators(X,Y)
        holds H.x = x * I" by A1,Th38;

    consider L be Lipschitzian LinearOperator of
      R_NormSpace_of_BoundedLinearOperators(Z,Y),
      R_NormSpace_of_BoundedLinearOperators(Z,W)
    such that
    A3: L is one-to-one onto isometric
      & for x be Point of R_NormSpace_of_BoundedLinearOperators(Z,Y)
        holds L.x = J * x by A1,Th37;

    reconsider K = L * H as Lipschitzian LinearOperator of
      R_NormSpace_of_BoundedLinearOperators(X,Y),
      R_NormSpace_of_BoundedLinearOperators(Z,W) by LOPBAN_2:2;

    take K;
    thus K is one-to-one onto by A2,A3,FUNCT_2:27;

    for x be Point of R_NormSpace_of_BoundedLinearOperators(X,Y)
    holds ||.K.x.|| = ||.x.||
    proof
      let x be Point of R_NormSpace_of_BoundedLinearOperators(X,Y);
      thus ||.K.x.||
       = ||.L.(H.x).|| by FUNCT_2:15
      .= ||.H.x.|| by NDIFF_7:7,A3
      .= ||.x.|| by A2,NDIFF_7:7;
    end;
    hence K is isometric by NDIFF_7:7;

    let x be Point of R_NormSpace_of_BoundedLinearOperators(X,Y);
    thus K.x
     = L.(H.x) by FUNCT_2:15
    .= J * (H.x) by A3
    .= J * (x * I") by A2;
  end;
