reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);
reserve D for non empty set,
  bD for FinSequence of D,
  b,f,g for FinSequence of K,
  MD for Matrix of D;

theorem Th39:
  X in Solutions_of(A9,B9) & j in Seg m implies X in Solutions_of(
  RLine(A9,i,Line(A9,i) + a*Line(A9,j)), RLine(B9,i,Line(B9,i) + a*Line(B9,j)))
proof
  assume that
A1: X in Solutions_of(A9,B9) and
A2: j in Seg m;
  consider X1 such that
A3: X = X1 and
A4: len X1 = width A9 and
A5: width X1 = width B9 and
A6: A9 * X1 = B9 by A1;
  set LAj=Line(A9,j);
  set LAi=Line(A9,i);
  set RA=RLine(A9,i,LAi+a*LAj);
A7: len (LAi+a*LAj) = width A9 by CARD_1:def 7;
  then
A8: len RA = len A9 by MATRIX11:def 3;
  set RX=RA*X1;
A9: width RA = width A9 by A7,MATRIX11:def 3;
  then
A10: len RX = len RA & width RX=width X1 by A4,MATRIX_3:def 4;
A11: len A9 = len B9 by A1,Th33;
  then dom B9=Seg len RA by A8,FINSEQ_1:def 3;
  then
A12: Indices RX = Indices B9 by A5,A10,FINSEQ_1:def 3;
  set LBj=Line(B9,j);
  set LBi=Line(B9,i);
  set RB=RLine(B9,i,LBi+a*LBj);
A13: Indices RB = Indices B9 by MATRIX_0:26;
A14: len (LBi+a*LBj) = width B9 by CARD_1:def 7;
  then
A15: width RB = width B9 by MATRIX11:def 3;
A16: len (a*LAj) = width A9 & len LAi = width A9 by CARD_1:def 7;
A17: now
A18: rng (a*LBj) c= the carrier of K by FINSEQ_1:def 4;
    let o,p be Nat such that
A19: [o,p] in Indices RB;
A20: o in dom B9 by A13,A19,ZFMISC_1:87;
A21: B9*(o,p) = Line(A9,o) "*" Col(X1,p) by A4,A6,A13,A19,MATRIX_3:def 4;
    reconsider CX=Col(X1,p) as Element of (width A9)-tuples_on the carrier of
    K by A4;
A22: len Col(X1,p)=width A9 by A4,MATRIX_0:def 8;
A23: p in Seg width B9 by A13,A19,ZFMISC_1:87;
    then B9*(o,p)=Line(B9,o).p & B9*(j,p)=LBj.p by MATRIX_0:def 7;
    then reconsider
    LBop = Line(B9,o).p,LBjp = LBj.p as Element of the carrier of K;
    p in dom (a*LBj) by A23,FINSEQ_2:124;
    then (a*LBj).p in rng (a*LBj) by FUNCT_1:def 3;
    then reconsider aLBjp=(a*Line(B9,j)).p as Element of K by A18;
    len B9 = m by MATRIX_0:def 2;
    then
A24: dom B9=Seg m by FINSEQ_1:def 3;
    then [j,p] in Indices B9 by A2,A23,ZFMISC_1:87;
    then
A25: B9*(j,p) = LAj"*"Col(X1,p ) by A4,A6,MATRIX_3:def 4;
    now
      per cases;
      suppose
A26:    o=i;
        then Line(RA,o)=LAi+a*LAj by A7,A20,A24,MATRIX11:28;
        hence RX*(o,p) = (LAi+a*LAj) "*" CX by A4,A9,A12,A13,A19,MATRIX_3:def 4
          .= Sum(mlt(LAi,CX)+mlt(a*LAj,CX)) by A16,A22,MATRIX_4:56
          .= Sum(mlt(LAi,CX)+a*mlt(LAj,CX)) by FVSUM_1:68
          .= Sum(mlt(LAi,CX))+Sum(a*mlt(LAj,CX)) by FVSUM_1:76
          .= B9*(o,p)+a*(B9*(j,p)) by A21,A25,A26,FVSUM_1:73
          .= LBop+a*(B9*(j,p)) by A23,MATRIX_0:def 7
          .= LBop+a*LBjp by A23,MATRIX_0:def 7
          .= LBop+aLBjp by A23,FVSUM_1:51
          .= (LBi+a*LBj).p by A23,A26,FVSUM_1:18
          .= RB*(o,p) by A14,A13,A19,A26,MATRIX11:def 3;
      end;
      suppose
A27:    o<>i;
        then Line(RA,o)=Line(A9,o) by A20,A24,MATRIX11:28;
        hence RX*(o,p) = Line(A9,o)"*"Col(X1,p) by A4,A9,A12,A13,A19,
MATRIX_3:def 4
          .= B9*(o,p) by A4,A6,A13,A19,MATRIX_3:def 4
          .= RB*(o,p) by A14,A13,A19,A27,MATRIX11:def 3;
      end;
    end;
    hence RB*(o,p) = RX*(o,p);
  end;
  len RB = len B9 by A14,MATRIX11:def 3;
  then RX=RB by A5,A11,A8,A15,A10,A17,MATRIX_0:21;
  hence thesis by A3,A4,A5,A9,A15;
end;
