
theorem Th39:
  for X be non empty set, S be SigmaField of X, M be sigma_Measure
of S, f be PartFunc of X,ExtREAL,c be Real st f is_simple_func_in S holds c(#)f
  is_simple_func_in S
proof
  let X be non empty set;
  let S be SigmaField of X;
  let M be sigma_Measure of S;
  let f be PartFunc of X,ExtREAL;
  let c be Real;
  set g = c(#)f;
  assume
A1: f is_simple_func_in S;
  then consider G be Finite_Sep_Sequence of S such that
A2: dom f = union rng G and
A3: for n be Nat, x,y be Element of X st n in dom G & x in G.n & y in G
  .n holds f.x = f.y by MESFUNC2:def 4;
A4: f is real-valued by A1,MESFUNC2:def 4;
  now
    let x be Element of X;
    assume
A5: x in dom g;
     c * f.x <> -infty by A4;
    then g.x <> -infty by A5,MESFUNC1:def 6;
    then -infty < g.x by XXREAL_0:6;
    then
A6: -(+infty) < g.x by XXREAL_3:def 3;
     c * f.x <> +infty by A4;
    then g.x <> +infty by A5,MESFUNC1:def 6;
    then g.x < +infty by XXREAL_0:4;
    hence |. g.x .| < +infty by A6,EXTREAL1:22;
  end;
  then
A7: g is real-valued by MESFUNC2:def 1;
A8: dom g = dom f by MESFUNC1:def 6;
  now
    let n be Nat;
    let x,y be Element of X;
    assume that
A9: n in dom G and
A10: x in G.n and
A11: y in G.n;
A12: G.n in rng G by A9,FUNCT_1:3;
    then y in dom g by A8,A2,A11,TARSKI:def 4;
    then
A13: g.y = ( c)*f.y by MESFUNC1:def 6;
    x in dom g by A8,A2,A10,A12,TARSKI:def 4;
    then g.x = ( c)*f.x by MESFUNC1:def 6;
    hence g.x = g.y by A3,A9,A10,A11,A13;
  end;
  hence thesis by A8,A7,A2,MESFUNC2:def 4;
end;
