reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;

theorem
  for f be PartFunc of CNS,RNS, x0 be Point of CNS st f is_continuous_in
  x0 holds ||. f .|| is_continuous_in x0 & -f is_continuous_in x0
proof
  let f be PartFunc of CNS,RNS;
  let x0 be Point of CNS;
  assume
A1: f is_continuous_in x0;
  then
A2: x0 in dom f;
  now
    thus
A3: x0 in dom (||.f .||) by A2,NORMSP_0:def 3;
    let s1 be sequence of CNS;
    assume that
A4: rng s1 c= dom(||.f .||) and
A5: s1 is convergent & lim s1=x0;
A6: rng s1 c= dom f by A4,NORMSP_0:def 3;
    then
A7: f/.x0 = lim (f/*s1) by A1,A5;
A8: f/*s1 is convergent by A1,A5,A6;
    then ||.f/*s1.|| is convergent by NORMSP_1:23;
    hence ||.f.||/*s1 is convergent by A6,Th30;
    thus ||.f.||/.x0 =||.f.||.x0 by A3,PARTFUN1:def 6
      .= ||.f/.x0 .|| by A3,NORMSP_0:def 3
      .= lim ||.f/*s1 .|| by A8,A7,LOPBAN_1:41
      .= lim (||.f.||/*s1) by A6,Th30;
  end;
  hence ||.f .|| is_continuous_in x0;
  -f=(-1)(#)f by VFUNCT_1:23;
  hence thesis by A1,Th36;
end;
