reserve a,b,c,v,v1,x,y for object;
reserve V,A for set;
reserve d for TypeSCNominativeData of V,A;
reserve p,q,r for SCPartialNominativePredicate of V,A;
reserve n for Nat;
reserve X for Function;
reserve f,g,h for SCBinominativeFunction of V,A;

theorem
  for x being Element of product <*g*> st
   v in V & product <*g*> <> {} holds
  SC_Fsuperpos(f,g,v) = SC_Fsuperpos(f,x,<*v*>)
  proof
    set G = <*g*>;
    let x be Element of product G;
    assume that
A1: v in V and
A2: product G <> {};
    set X = <*v*>;
    set S1 = SC_Fsuperpos(f,g,v);
    set S2 = SC_Fsuperpos(f,x,X);
    defpred A[object] means $1 in_doms G;
A3: G.1 = g;
A4: dom G = {1} by FINSEQ_1:2,38;
A5: dom(S1) = {d where d is TypeSCNominativeData of V,A:
    local_overlapping(V,A,d,g.d,v) in dom f & d in dom g} by Def15;
    S2 = SCFsuperpos(G,X).(f,x) by A2,Def14;
    then
A6: dom(S2) = {d where d is TypeSCNominativeData of V,A:
    global_overlapping(V,A,d,NDentry(G,X,d)) in dom f & A[d]} by A2,Def13;
    thus
A7: dom S1 = dom S2
    proof
      thus dom S1 c= dom S2
      proof
        let a be object;
        assume a in dom S1;
        then consider d such that
A8:     d = a and
A9:     local_overlapping(V,A,d,g.d,v) in dom f and
A10:    d in dom g by A5;
A11:    A[d]
        proof
          let x;
          thus thesis by A10,A3,A4,TARSKI:def 1;
        end;
        NDentry(G,X,d) = naming(V,A,v,g.d) by A1,A10,Th26;
        hence thesis by A8,A9,A11,A6;
      end;
      let a be object;
      assume a in dom S2;
      then consider d such that
A12:  a = d and
A13:  global_overlapping(V,A,d,NDentry(G,X,d)) in dom f and
A14:  A[d] by A6;
      1 in dom G by A4,TARSKI:def 1;
      then
A15:  d in dom(G.1) by A14,Def3;
      then local_overlapping(V,A,d,g.d,v) in dom f by A1,Th26,A13;
      hence thesis by A5,A12,A15;
    end;
    let a be object;
    assume
A16: a in dom S1;
    then consider d such that
A17: d = a and
    local_overlapping(V,A,d,g.d,v) in dom f and
A18: d in dom g by A5;
    NDentry(G,X,d) = naming(V,A,v,g.d) by A1,A18,Th26;
    hence S2.a = f.local_overlapping(V,A,d,g.d,v) by A7,A16,A17,A2,Th36
    .= S1.a by A16,A17,Th37;
  end;
