reserve A,A1,A2,B,C,D for Ordinal,
  X,Y for set,
  x,y,a,b,c for object,
  L,L1,L2,L3 for Sequence,
  f for Function;
reserve fi,psi for Ordinal-Sequence;

theorem Th39:
  1*^A = A & A*^1 = A
proof
  defpred P[Ordinal] means $1*^succ 0 = $1;
  thus 1*^A = 0*^A +^ A by Lm1,Th36
    .= 0 +^ A by Th35
    .= A by Th30;
A1: for A st for B st B in A holds P[B] holds P[A]
  proof
    let A such that
A2: for B st B in A holds B*^(succ 0) = B;
A3: now
      deffunc F(Ordinal) = $1*^succ 0;
      assume that
A4:   A <> 0 and
A5:   for B holds A <> succ B;
      consider fi such that
A6:   dom fi = A & for D st D in A holds fi.D = F(D) from OSLambda;
A7:   A = rng fi
      proof
        thus A c= rng fi
        proof
          let x be object;
          assume
A8:       x in A;
          then reconsider B = x as Ordinal;
          x = B*^succ 0 by A2,A8
            .= fi.x by A6,A8;
          hence thesis by A6,A8,FUNCT_1:def 3;
        end;
        let x be object;
        assume x in rng fi;
        then consider y being object such that
A9:     y in dom fi and
A10:    x = fi.y by FUNCT_1:def 3;
        reconsider y as Ordinal by A9;
        fi.y = y*^succ 0 by A6,A9
          .= y by A2,A6,A9;
        hence thesis by A6,A9,A10;
      end;
A11:  A is limit_ordinal by A5,ORDINAL1:29;
      then A*^succ 0 = union sup fi by A4,A6,Th37
        .= union sup rng fi;
      hence A*^succ 0 = union A by A7,Th18
        .= A by A11;
    end;
    now
      given B such that
A12:  A = succ B;
      thus A*^(succ 0) = B*^(succ 0) +^ succ 0 by A12,Th36
        .= B +^ succ 0 by A2,A12,ORDINAL1:6
        .= succ(B +^ 0) by Th28
        .= A by A12,Th27;
    end;
    hence thesis by A3,Th35;
  end;
  for A holds P[A] from ORDINAL1:sch 2(A1);
  hence thesis;
end;
