reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;

theorem Th39:
  N-min L~f in rng f
proof
  set p = N-min L~f;
A1: len f >= 2 by NAT_D:60;
  consider i be Nat such that
A2: 1 <= i and
A3: i+1 <= len f and
A4: p in LSeg(f/.i,f/.(i+1)) by SPPOL_2:14,SPRECT_1:11;
  i+1 >= 1 by NAT_1:11;
  then
A5: i+1 in dom f by A3,FINSEQ_3:25;
  then f/.(i+1) in L~f by A1,GOBOARD1:1;
  then
A6: (f/.(i+1))`2 <= N-bound L~f by PSCOMP_1:24;
A7: p`2 = N-bound L~f by EUCLID:52;
  i <= i+1 by NAT_1:11;
  then i <= len f by A3,XXREAL_0:2;
  then
A8: i in dom f by A2,FINSEQ_3:25;
  then f/.i in L~f by A1,GOBOARD1:1;
  then
A9: (f/.i)`2 <= N-bound L~f by PSCOMP_1:24;
  now
    per cases by A4,A9,A6,A7,Th18;
    suppose
      p = f/.i;
      hence thesis by A8,PARTFUN2:2;
    end;
    suppose
      p = f/.(i+1);
      hence thesis by A5,PARTFUN2:2;
    end;
    suppose
A10:  p`2 = (f/.i)`2 & p`2 = (f/.(i+1))`2;
      then f/.(i+1) in N-most L~f by A1,A5,A7,Th10,GOBOARD1:1;
      then
A11:  (f/.(i+1))`1 >= p`1 by PSCOMP_1:39;
      (f/.i)`1 <= (f/.(i+1))`1 or (f/.(i+1))`1 <= (f/.i)`1;
      then
A12:  (f/.i)`1 <= p`1 or (f/.(i+1))`1 <= p`1 by A4,TOPREAL1:3;
      f/.i in N-most L~f by A1,A8,A7,A10,Th10,GOBOARD1:1;
      then (f/.i)`1 >= p`1 by PSCOMP_1:39;
      then p`1 = (f/.i)`1 or p`1 = (f/.(i+1))`1 by A11,A12,XXREAL_0:1;
      then p = (f/.i) or p = (f/.(i+1)) by A10,TOPREAL3:6;
      hence thesis by A8,A5,PARTFUN2:2;
    end;
  end;
  hence thesis;
end;
